In function "shell" this line display shell buffer and almost always its open new shell in random frame. And I have to swap the buffers, it's annoying.
...
(pop-to-buffer buffer)
...
In docs says:
If that window is on a different graphical frame, that frame is given input focus if possible.
I don't understand how I can display buffer in target frame, I'm not good enough in elisp. How I can do that? Thanks if someone could help.
I am assuming that the original poster means targeting the currently selected window in the same frame. In the event the original poster is desirous of targeting a specific window in a different frame, then see this related thread for a complex example: https://stackoverflow.com/questions/18346785/how-to-intercept-a-file-before-it-opens-and-decide-which-frame
I copied the built-in function shell and created a new one called shell-get-buffer-create, which uses with-current-buffer ... instead of pop-to-buffer. This new function generates or locates the *shell* buffer without selecting it in any window.
To display the *shell* buffer in the currently selected window use:
(switch-to-buffer (shell-get-buffer-create))
or
(pop-to-buffer-same-window (shell-get-buffer-create))
or
(set-window-buffer (selected-window) (shell-get-buffer-create))
I created a custom function called my-display-buffer that can display in four directions -- left, right, above, or below. There are three possibilities: (1) If a window on the frame already displays the target buffer, then just reuse the same window. (2) If there is already a window in the specified direction in relation to the selected window, then display the target buffer in said window. (3) If there is no window in the specified direction, then create one in that direction and display the target buffer in said window.
Sample Usage:
(my-display-buffer (shell-get-buffer-create) nil 'left)
or
(my-display-buffer (shell-get-buffer-create) nil 'right)
or
(my-display-buffer (shell-get-buffer-create) nil 'above)
or
(my-display-buffer (shell-get-buffer-create) nil 'below)
The Code:
(require 'shell)
(defun shell-get-buffer-create (&optional buffer)
"Run an inferior shell, with I/O through BUFFER (which defaults to `*shell*').
Interactively, a prefix arg means to prompt for BUFFER.
If `default-directory' is a remote file name, it is also prompted
to change if called with a prefix arg.
If BUFFER exists but shell process is not running, make new shell.
If BUFFER exists and shell process is running, just switch to BUFFER.
Program used comes from variable `explicit-shell-file-name',
or (if that is nil) from the ESHELL environment variable,
or (if that is nil) from `shell-file-name'.
If a file `~/.emacs_SHELLNAME' exists, or `~/.emacs.d/init_SHELLNAME.sh',
it is given as initial input (but this may be lost, due to a timing
error, if the shell discards input when it starts up).
The buffer is put in Shell mode, giving commands for sending input
and controlling the subjobs of the shell. See `shell-mode'.
See also the variable `shell-prompt-pattern'.
To specify a coding system for converting non-ASCII characters
in the input and output to the shell, use \\[universal-coding-system-argument]
before \\[shell]. You can also specify this with \\[set-buffer-process-coding-system]
in the shell buffer, after you start the shell.
The default comes from `process-coding-system-alist' and
`default-process-coding-system'.
The shell file name (sans directories) is used to make a symbol name
such as `explicit-csh-args'. If that symbol is a variable,
its value is used as a list of arguments when invoking the shell.
Otherwise, one argument `-i' is passed to the shell.
\(Type \\[describe-mode] in the shell buffer for a list of commands.)"
(interactive
(list
(and current-prefix-arg
(prog1
(read-buffer "Shell buffer: "
;; If the current buffer is an inactive
;; shell buffer, use it as the default.
(if (and (eq major-mode 'shell-mode)
(null (get-buffer-process (current-buffer))))
(buffer-name)
(generate-new-buffer-name "*shell*")))
(if (file-remote-p default-directory)
;; It must be possible to declare a local default-directory.
;; FIXME: This can't be right: it changes the default-directory
;; of the current-buffer rather than of the *shell* buffer.
(setq default-directory
(expand-file-name
(read-directory-name
"Default directory: " default-directory default-directory
t nil))))))))
(setq buffer (if (or buffer (not (derived-mode-p 'shell-mode))
(comint-check-proc (current-buffer)))
(get-buffer-create (or buffer "*shell*"))
;; If the current buffer is a dead shell buffer, use it.
(current-buffer)))
;; On remote hosts, the local `shell-file-name' might be useless.
(if (and (called-interactively-p 'any)
(file-remote-p default-directory)
(null explicit-shell-file-name)
(null (getenv "ESHELL")))
(with-current-buffer buffer
(set (make-local-variable 'explicit-shell-file-name)
(file-remote-p
(expand-file-name
(read-file-name
"Remote shell path: " default-directory shell-file-name
t shell-file-name))
'localname))))
;; The buffer's window must be correctly set when we call comint (so
;; that comint sets the COLUMNS env var properly).
(with-current-buffer buffer
(unless (comint-check-proc buffer)
(let* ((prog (or explicit-shell-file-name
(getenv "ESHELL") shell-file-name))
(name (file-name-nondirectory prog))
(startfile (concat "~/.emacs_" name))
(xargs-name (intern-soft (concat "explicit-" name "-args"))))
(unless (file-exists-p startfile)
(setq startfile (concat user-emacs-directory "init_" name ".sh")))
(apply 'make-comint-in-buffer "shell" buffer prog
(if (file-exists-p startfile) startfile)
(if (and xargs-name (boundp xargs-name))
(symbol-value xargs-name)
'("-i")))
(shell-mode))))
buffer)
(defun my-display-buffer (buffer alist direction &optional size pixelwise)
"BUFFER: The buffer that will be displayed.
ALIST: See the doc-string of `display-buffer' for more information.
DIRECTION: Must use one of these symbols: 'left 'right 'below 'above
SIZE: See the doc-string for `split-window'.
PIXELWISE: See the doc-string for `split-window'.
There are three possibilities:
- (1) If a window on the frame already displays the target buffer,
then just reuse the same window.
- (2) If there is already a window in the specified direction in relation
to the selected window, then display the target buffer in said window.
- (3) If there is no window in the specified direction, then create one
in that direction and display the target buffer in said window."
(let ((window
(cond
((get-buffer-window buffer (selected-frame)))
((window-in-direction direction))
(t
(split-window (selected-window) size direction pixelwise)))))
(window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
window))
And, here is an eshell-get-buffer-create that works the same as above ...
(require 'cl)
(require 'eshell)
(defun eshell-get-buffer-create (&optional arg)
"Create an interactive Eshell buffer. Return the Eshell buffer,
creating it if needed. The buffer used for Eshell sessions is
determined by the value of `eshell-buffer-name'. A numeric prefix
arg (as in `C-u 42 M-x eshell RET') switches to the session with
that number, creating it if necessary. A nonnumeric prefix arg
means to createa new session. Returns the buffer selected (or created)."
(interactive "P")
(cl-assert eshell-buffer-name)
(let ((buf (cond ((numberp arg)
(get-buffer-create (format "%s<%d>"
eshell-buffer-name
arg)))
(arg
(generate-new-buffer eshell-buffer-name))
(t
(get-buffer-create eshell-buffer-name)))))
(cl-assert (and buf (buffer-live-p buf)))
(with-current-buffer buf
(unless (derived-mode-p 'eshell-mode)
(eshell-mode)))
buf))
Not a direct answer to your question, but maybe this is a solution for you.
M-x install-package shell-pop
To install the package shell-pop from melpa or melpa-stable.
Then evaluate (for tryout in *scratch* via C-x C-e, later in your .emacs)
(global-set-key (kbd "<C-M-return>") 'shell-pop)
This pops up a shell in the lower part of your frame, in this case when pressing ctrl-meta-ret. Repeating the keyboard sequence returns back where you were.
See https://github.com/kyagi/shell-pop-el for details.
I use the following to remap the shell command:
(defun new-shell (original-shell &optional buffer name)
(let ((currentbuf (get-buffer-window (current-buffer)))
(newbuf (generate-new-buffer-name "*shell*")))
(generate-new-buffer newbuf)
(set-window-dedicated-p currentbuf nil)
(set-window-buffer currentbuf newbuf)
(funcall original-shell newbuf)))
;; Remap shell to new-shell
(advice-add 'shell :around #'new-shell)
This not only opens a shell in the same buffer, but lets you open as many shells as you like.
