kill-buffer with y-or-n-p instead of yes-or-no-p

Question

Q:  How can I use y-or-n-p -- instead of yes-or-no-p -- when calling kill-buffer for just the duration of a particular function?

In other words, I want the behavior of (fset 'yes-or-no-p 'y-or-n-p) but only for the duration of a particular function without any lasting effect.

CAVEAT:  I would like to please avoid using (fset 'yes-or-no-p 'y-or-n-p) at the outset and (fset 'yes-or-no-p 'yes-or-no-p) at the tail end of the function, just in case I decide to exit out of the function with a 'quit signal such as C-g, in which case the effect would become long-lasting rather than merely temporary.

Here is a test snippet to start with:

(let* (
    (filename "/private/tmp/foofile")
    (buf (get-buffer-create "*foo*")))
  (with-current-buffer buf
    (write-file filename)
    (insert "Every good boy deserves fudge."))
  (kill-buffer buf)
  (delete-file filename))

Answer 1

Advice kill-buffer:

(defun yes-or-no-p->-y-or-n-p (orig-fun &rest r)
  (cl-letf (((symbol-function 'yes-or-no-p) #'y-or-n-p))
    (apply orig-fun r)))

(advice-add 'kill-buffer :around #'yes-or-no-p->-y-or-n-p)

or advice yes-or-no-p

(defun yes-or-no-p@maybe-just-y-or-n-p (orig-fun prompt)
  (funcall
   (if (eq this-command 'kill-buffer)
       #'y-or-n-p
     #'yes-or-no-p)
   prompt))

(advice-add 'yes-or-no-p :around #'yes-or-no-p@maybe-just-y-or-n-p)

Answer 2

just in case I decide to exit out of the function with a 'quit signal such as C-g, in which case the effect would become long-lasting rather than merely temporary.

This can be solved with unwind-protect. The following function always restores yes-or-no-p's definition at the end even if you quit in the middle of it:

(defun my/kill-buffer ()
  (interactive)
  (let ((yes-or-no-def (symbol-function 'yes-or-no-p)))
    (unwind-protect
        (progn
          (fset 'yes-or-no-p 'y-or-n-p)
          (call-interactively #'kill-buffer))
      (fset 'yes-or-no-p yes-or-no-def))))

Answer 3

I think the best way to handle this is to use cl-letf, like so:

(require 'cl-lib)
(cl-letf (((symbol-function 'yes-or-no-p) #'y-or-n-p))
  (let* ((filename "~/private/tmp/foofile")
         (buf (get-buffer-create "*foo*")))
    (with-current-buffer buf
      (write-file filename)
      (insert "Every good boy deserves fudge."))
    (kill-buffer buf)
    (delete-file filename)))

This is in principle similar to whacka's answer, but avoids requiring an explicit unwind-protect.