Only open files which should be opened via Emacs via RET in dired

Question

I got

;; Opens files externally from dired.
(defun dired-open-file ()
  "In dired, open the file named on this line."
  (interactive)
  (let* ((file (dired-get-filename nil t)))
    (message "Opening %s" file)
    (call-process "xdg-open" nil 0 nil file)
    (message "Opened %s" file)))
(eval-after-load "dired"
    '(define-key dired-mode-map (kbd "C-c o") 'dired-open-file))

in my init file so I can use dired to open PDFs, videos, etc. in applications like Evince or MPV. However, because I'm stupid, I keep hitting RET when wanting to view a PDF or watch a video which then causes Emacs to freeze.

How can I make dired only open files the way it currently does when I hit RET if xdg-open would open it with Emacs, and otherwise invoke xdg-open to open the file externally?

Note that I don't always want xdg-open to be invoked when I hit RET on file because that'd mean a new Emacs instance would be launched every time I open a simple text file via dired.

---

There is an answer which enables distinction based on the file name extension. This, however, does not work for me as I have many text files without any file name extension but also pictures and PDFs without file name extensions. xdg-open (and thereby file browsers like Nautilus) manage to open these files using the correct application because xdg-open can distinguish file type based on their magic numbers.

Answer 1

You can use the file command to get the mime type and a list of supported types to automagically open a file in emacs if supported and with an external editor if not. A rough implementation is

(defvar supported-mime-types
  '("text/english"
    "text/plain"
    "text/x-makefile"
    "text/x-c++hdr"
    "text/x-c++src"
    "text/x-chdr"
    "text/x-csrc"
    "text/x-java"
    "text/x-moc"
    "text/x-pascal"
    "text/x-tcl"
    "text/x-tex"
    "application/x-shellscript"
    "text/x-c"
    "text/x-c++"
    "inode/directory"))

(load "subr-x")

(defun get-mimetype (filepath)
  (string-trim
   (shell-command-to-string (concat "file -b --mime-type "
                                    (shell-quote-argument filepath))))

(defun dired-find-file-dwim ()
  (interactive)
  (let ((file (dired-get-filename nil t)))
    (if (member (get-mimetype file) supported-mime-types)
        (find-file file)
      (call-process "xdg-open" nil 0 nil file))))

(with-eval-after-load 'dired
  (define-key dired-mode-map (kbd "RET") #'dired-find-file-dwim))

The choice of better names and the documentation is left as an exercise to the reader.

Answer 2

Customize option dired-guess-shell-alist-user, then use ! (dired-do-shell-command) to act on a file or directory in a Dired listing. The default action will do what you want, according to your dired-guess-shell-alist-user settings. (You need to load standard libraries dired-aux.el and dired-x.el for this feature.)

C-h v tells you:

dired-guess-shell-alist-user is a variable defined in dired-x.el.

Its value is nil

Documentation:

User-defined alist of rules for suggested commands.

These rules take precedence over the predefined rules in the variable dired-guess-shell-alist-default (to which they are prepended).

Each element of this list looks like

(REGEXP COMMAND...)

where each COMMAND can either be a string or a Lisp expression that evaluates to a string. This expression can access the file name as the variable file.

If several COMMANDs are given, the first one will be the default and the rest will be added temporarily to the history and can be retrieved with M-x previous-history-element (M-) .

The variable dired-guess-shell-case-fold-search controls whether REGEXP is matched case-sensitively.

You can set this variable in your ~/.emacs. For example, to add rules for .foo and .bar files, write

(setq dired-guess-shell-alist-user
    '(("\\.foo\\'" "FOO-COMMAND")
      ("\\.bar\\'"
       (if condition
          "BAR-COMMAND-1"
        "BAR-COMMAND-2"))))

You can customize this variable.