How to unbind and then repurpose a default keybinding?

Question

I want to test out a few alternative keybinding setups but I’m not sure what the simplest/most effective way to do that is.

I would like to have it so that instead of C-d being forward delete ("delete-char" which is what it is by default), whenever I hold down C-d I can use the left (kbd <left>?) and right (kbd <right>?) arrow keys to delete backwards and forwards.

I can can’t even get unsetting C-d to work: When I put (global-set-key (kbd "C-d") 'nil) in my init.el and eval-last-sexp, C-d seems to actually be disabled. But if I save-buffer and close emacs, when I open a new instance, C-d is back to being a forward delete.

Once I get past that problem, the next problem is figuring out how to even express "while C-d is pressed, <left> and <right> arrow keys trigger delete-backwards-char and delete-char and if either are held down they will repeatedly call their functions" in the init file in elisp.

If I can get this resolved the proper way, I can apply the solution to repurpose other default keybindings, but at this point I can't imagine solving this single case without some real guidance.

Answer 1

To find the key representation you can do this:

1. C-x b *scratch*
2. Type whatever key you are interested in. Don't bother about what Emacs does or doesn't do when you type those keys. In your case you would type Ctrl-d, followed by Right Arrow.
3. Do C-h l. You will see the following entries

 C-d     ;; delete-char
 <right> ;; right-char
 C-h l   ;; view-lossage

• Portion before the ;; says what keys you pressed. The portion after ;; says the command they run. Based on the above information you know that Ctrl-d followed by Right Arrow is same as C-d <right>. So, to bind a command to Ctrl-d RightArrow you need to use (kbd "C-d <right>")

• You want C-d <right> to run what C-d does. The lossage says C-d is mapped to delete-char. So, you would do

(global-set-key (kbd "C-d <right>") 'delete-char)

4. When you put the above code in .emacs and re-start Emacs you will see the following error message

global-set-key: Key sequence C-d <right> starts with non-prefix key C-d

The above message is a fancy way of saying that you need to unbind C-d. You already know C-d is written as (kbd "C-d"). So, you add

(global-unset-key (kbd "C-d"))

before you global-set-key.

---

This is the lossage information for all the keys that are relevant to the question

 C-d         ;; delete-char
 <backspace> ;; backward-delete-char-untabify
 C-d         ;; delete-char
 <right>     ;; right-char
 C-d         ;; delete-char
 <left>      ;; left-char
 C-h l       ;; view-lossage

If you follow the above process, this is what you will end up with in your ~/.emacs.

(global-unset-key (kbd "C-d"))
(global-set-key (kbd "C-d <right>") 'delete-char)
(global-set-key (kbd "C-d <left>") 'backward-delete-char-untabify)

Answer 2

You need to save the configuration in your ~/.emacs.

1. C-x C-f ~/.emacs
2. Copy the following elisp snippet in to your ~/.emacs

(global-unset-key (kbd "C-d"))

(defvar my-Ctrl-d-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "<right>") 'delete-char)
    (define-key map (kbd "<left>") 'delete-backward-char)
    map))
    
(fset 'my-Ctrl-d-map my-Ctrl-d-map)

(map-keymap
 (lambda (key cmd)
   (put cmd 'repeat-map 'my-Ctrl-d-map))
 my-Ctrl-d-map)

(repeat-mode -1)
(repeat-mode 1)

(global-set-key (kbd "C-d") 'my-Ctrl-d-map)

3. Restart Emacs.

Note that repeat-mode is available in Emacs >= 28.1