Is there any way of making eshell aliases using bash and zsh aliases syntax?

Question

Let's say I have a file called .alias in my $HOME directory with the following content:

alias "my-first-alias"="ls -lha"
alias "my-second-alias="echo 'Hello World'"

I know that if put the line source "$HOME/.alias" in both my .bashrc and .zshrc files I'll be able to create aliases on these shells at the same time in a single file, just so I don't have to manually copy one alias that I have just created in .bashrc to .zshrc...

So far everything is fine... The problem starts with eshell, its alias syntax is different, the last two aliases in eshell syntax would be the following:

alias my-first-alias 'ls -lha'
alias my-second-alias 'echo "Hello World"'

Since its syntax is different I can't just source my .alias file for eshell, I wouldn't like to manually translate my aliases for the eshell syntax all the times that I create a new alias. Is there any standard way of solving problems like this on emacs? Or should I be thinking about how to create a script that will translate my bash aliases to eshell aliases for sourcing it?

Answer 1

If you go over to EshellAlias on EmacsWiki, there are many solutions to this problem. The one by Edgar Vincent that's currently at the very bottom of the page is the most concise and elegant solution so far.

  (defun eshell-load-bash-aliases ()
    "Read Bash aliases and add them to the list of eshell aliases."
    ;; Bash needs to be run - temporarily - interactively
    ;; in order to get the list of aliases.
      (with-temp-buffer
        (call-process "bash" nil '(t nil) nil "-ci" "alias")
        (goto-char (point-min))
        (while (re-search-forward "alias \\(.+\\)='\\(.+\\)'$" nil t)
          (eshell/alias (match-string 1) (match-string 2)))))

  ;; We only want Bash aliases to be loaded when Eshell loads its own aliases,
  ;; rather than every time `eshell-mode' is enabled.
  (add-hook 'eshell-alias-load-hook 'eshell-load-bash-aliases)

It reads the output of bash -ci alias and loops through them to run eshell/alias on each alias it finds. It should implicitly load your $HOME/.alias file.

The function eshell/alias in the eshell-laod-bash-aliases above writes the list of aliases to the file eshell-aliases-file after each addition of one alias.
That may take long for long alias lists. The following version writes the list only after processing all aliases from bash.

(require 'cl-lib)

(defun eshell-load-bash-aliases ()
  "Read Bash aliases and add them to the list of eshell aliases."
  ;; Bash needs to be run - temporarily - interactively
  ;; in order to get the list of aliases.
  (with-temp-buffer
    (call-process "bash" nil '(t nil) nil "-ci" "alias")
    (goto-char (point-min))
    (cl-letf (((symbol-function 'eshell-write-aliases-list) #'ignore))
      (while (re-search-forward "alias \\(.+\\)='\\(.+\\)'$" nil t)
        (eshell/alias (match-string 1) (match-string 2))))
    (eshell-write-aliases-list)))

;; We only want Bash aliases to be loaded when Eshell loads its own aliases,
;; rather than every time `eshell-mode' is enabled.
(add-hook 'eshell-alias-load-hook 'eshell-load-bash-aliases)