How can I answer a minibuffer prompt from elisp?

Question

I occasionally find myself using interactive functions inside of a function that I'm writing for my own use. If a function asks for some information (e.g. "Output file: ~/") is there a general elisp way to add text to the minibuffer and then press enter so that the user doesn't have to do so?

As an example, suppose that I want to run org-latex-export-to-pdf inside of a function but I don't want the user to have to specify a file name. Running (org-latex-export-to-pdf) will move the point to the minibuffer, but putting something like (insert "filename.tex") on the next line doesn't seem to work.

Answer 1

Interesting problem. Looks like the editor runs the post-command-hook every time it enters a new command-loop, i.e. a recursive-edit. But we can start with minibuffer-setup-hook, which executes a function after entering the minibuffer. While this allows the inserting of input, it is too soon to exit the minibuffer, because the catch hasn't been setup yet.

(defmacro with-minibuffer-input (form &rest inputs)
  (declare (indent 1))
  `(minibuffer-with-setup-hook
       (lambda ()
         (minibuffer-input-provider ',inputs))
     ,form))

That's were we need to wrap the 'arguments' in our own 'command loop', which get's executed every time we enter a recursive-edit, at which point it pops one argument and throws one level up, via exit-minibuffer.

;; -*- lexical-binding: t -*-
(defun minibuffer-input-provider (inputs)
  (let ((hook (make-symbol "hook")))
    (fset hook (lambda ()
                 (remove-hook 'post-command-hook hook)
                 (when inputs
                   (when (= 0 (minibuffer-depth))
                     (error "Too many inputs"))
                   (when (cdr inputs)
                     (add-hook 'post-command-hook hook))
                   (insert (pop inputs))
                   (exit-minibuffer))))
    (add-hook 'post-command-hook hook)))


(with-minibuffer-input (call-interactively 'find-file)
  "/")

(with-minibuffer-input (call-interactively 'occur)
  "\\(foo\\)\\(bar\\)" "\\1");;C-u C-x C-e

;;foobar

(with-minibuffer-input (call-interactively 'replace-string)
  "foo" "bar")

;; foo

Answer 2

I wrote a macro for this called with-simulated-input, which you can get here. It allows you to provide arbitrary input as well as execute arbitrary lisp forms in order to simulate user interaction.

For example:

(with-simulated-input '("hello SPC" (insert "world") "RET")
  (read-string "Enter greeting: "))

would return "hello world", with the "hello " inserted by the first string, the "world" inserted via lisp code, and finally "RET" to finish the input.

It comes with a test suite that you can look at for more usage examples.

Answer 3

It seems that using run-with-timer with insert will get the job done.

(run-with-timer .2 nil 'insert "filename.tex")
(run-with-timer .3 nil 'execute-kbd-macro (kbd "RET"))
(org-latex-export-to-pdf)

The command insert when placed afterwards is coming up too quickly. It tries to insert the string before there is a place to insert it.