How to move point to the end of another buffer, using `with-current-buffer` and `goto-char`?

Question

I'm trying to implement «effective append» for log buffer, e.g. if a point is at point-max position then insert text and move point to new point-max, otherwise append text and preserve point position. I though this will be very trivial code:

(with-current-buffer
  (get-buffer-create "*scratch*")
  (if (eq (point) (point-max))
      (insert "\n;; ===\n")
    (save-excursion
      (goto-char (point-max))
      (insert "\n;; ===\n"))))

However, this works as expected only if invoked in *scratch* buffer:

• having point somewhere in the middle => text appended, point not moved
• having point at the end of buffer => text appended, point at the end

Now if I change buffer and invoke this command again, point never goes to new point-max and always stays where it was.

Simple tests showed that if statement gives correct results always, thus it is correct branch selected. I also tried explicitly move point or do scroll in true-branch, but nothing helped:

(if (eq (point) (point-max))
    (progn
      (insert "\n;; ===\n")
      (View-scroll-to-buffer-end)  ;; not works
      (goto-char (point-max)))     ;; so does it too
  (…))

Am I missing something?

Answer 1

I think the following code will help. It is modified from an example in the emacs-lisp intro at https://www.gnu.org/software/emacs/manual/html_node/eintr/append_002dto_002dbuffer-overview.html.

(defun append-string-to-buffer (buffer string)
  ;; Modified from append-to-buffer, defined in the emacs-lisp intro
  "Append to specified buffer the specified text.
It is inserted into that buffer at end of buffer.

When calling from a program, give two arguments:
BUFFER (or buffer name), and the STRING to be copied."
  (interactive
   (list (read-buffer "Append to buffer: " (other-buffer
                                            (current-buffer) t))
         (read-string "String to append: ")))

  (let* ((append-to (get-buffer-create buffer))
         (windows (get-buffer-window-list append-to t t))
         move-point-in-windows)
    (with-current-buffer append-to
      (barf-if-buffer-read-only)
      ;; record in which windows we should keep point at eob.
      (dolist (window windows)
        (when (= (window-point window) (point-max))
          (push window move-point-in-windows)))
      (let (return-to-position)
        ;; decide whether we should reset point to return-to-position
        ;; or leave it at eob.
        (unless (= (point) (point-max))
          (setq return-to-position (point))
          (goto-char (point-max)))
        (insert string)
        (when return-to-position
          (goto-char return-to-position)))
      ;; advance to point-max in windows where it is needed
      (dolist (window move-point-in-windows)
        (set-window-point window (point-max))))))

Answer 2

(with-current-buffer (get-buffer-create "MY-BUF")
  (let ((orig (point)))
    (if (eq (point) (point-max))
    (insert "\n;; ===\n")
      (goto-char (point-max))
      (insert "\n;; ===\n")
      (goto-char orig))))

BTW I'd not use save-excursion inside with-current-buffer, as save-excursion is a complex funciton, while goto-char orig looks cleaner.