5

After looking at this answer I find it hard to believe there is no way to clear the eShell.

Does anybody know of a short function or method to delete the entire buffer. Pressing C-l just scrolls the text, as soon as enter is pressed all of that text comes back.

Thanks

9

There is a function in the current development version, as you can see on the emacs-devel mailing list.

The function is very simple:

(defun eshell/clear ()
  "Clear the eshell buffer."
  (let ((inhibit-read-only t))
    (erase-buffer)
    (eshell-send-input)))

Typing clear in eshell will then result in clearing the buffer.

  • oh wow. how will i know when this is available in a main release? – Startec May 19 '15 at 8:57
  • You don't need to wait for the next release. You can just add this definition to your ~/.emacs.d/init.el file. You will know that it's available by checking for its definition with C-h f eshell/clear RET. – rekado May 19 '15 at 10:21
  • I am using an older version of Emacs which did not require (eshell-send-input) -- that line of code created an extra command prompt. – lawlist Sep 28 '17 at 17:47
5

This does it to one, insted of two lines.

;Clear the eshell buffer.
(defun eshell/clear ()      
   (let ((eshell-buffer-maximum-lines 0)) (eshell-truncate-buffer)))

Typing clear in eshell will then result in clearing the buffer.

  • 2
    Whoever left a demerit (downvote) without leaving a helpful constructive comment, please don't do that again -- especially when you see a newcomber to this forum! I am an intermediate Emacs user and I shouldn't have to sit here scratching my head to try and figure out why this answer received a downvote! It should not be necessary for me to try out the answer to maybe figure out why it was downvoted! – lawlist Sep 29 '17 at 5:23
  • 1
    If you add (interactive) after the defun declaration, all works as expected. – Paradiesstaub Jan 3 '18 at 3:02
  • 2
    Slightly better then default, clear, which doesn't seem to really clear. – Didier A. Aug 23 '18 at 5:14
2

While there is a built-in eshell/clear in recent versions of Emacs, it does something rather unfortunate: when there is unsent input at the current prompt, clearing the buffer sends the input. This can be problematic if the user has entered partial input.

The following version will clear the buffer while preserving unsent input. This is more comint-like.

(defun *-eshell-clear ()
  "Clear `eshell' buffer, comint-style."
  (interactive)
  (let ((input (eshell-get-old-input)))
    (eshell/clear-scrollback)
    (eshell-emit-prompt)
    (insert input)))
2

Running clear with 1, as in clear 1 works.

enter image description here.


How could you have found this out? We know we want to look for a function about eshell and it has to do with clear. So, why not do C-h f and type eshell clear. This produces two functions:

  1. eshell/clear-scrollback
  2. eshell/clear

If we select eshell-scrollback, Emacs shows us usage:

eshell/clear-scrollback is a compiled Lisp function in ‘esh-mode.el’.

(eshell/clear-scrollback)

Clear the scrollback content of the eshell window.

We try running eshell/clear-scrollback and it clears the screen. Ok, we can look at it's implementation but before that let's look at the other function eshell/clear. When we select that after C-h f and eshell clear, we get:

eshell/clear is an interactive compiled Lisp function in
‘esh-mode.el’.

(eshell/clear &optional SCROLLBACK)

Scroll contents of eshell window out of sight, leaving a blank window.
If SCROLLBACK is non-nil, clear the scrollback contents.

This tells us that we could run clear 1 to clear the screen. But, why are there two functions? If we look at the implementation of eshell/clear, we can see that the other function is actually used in it. To find the implementation simply click on the esh-mode.el in the usage buffer of eshell/clear.

(defun eshell/clear (&optional scrollback)
  "Scroll contents of eshell window out of sight, leaving a blank window.
If SCROLLBACK is non-nil, clear the scrollback contents."
  (interactive)
  (if scrollback
      (eshell/clear-scrollback)
    (insert (make-string (window-size) ?\n))
    (eshell-send-input)))

You can see that at the end this function sends any input which was present at the time of clearing the screen. To get around it, I wrote this little function:

(defun run-this-in-eshell (cmd)
  "Runs the command 'cmd' in eshell."
  (with-current-buffer "*eshell*"
    (eshell-kill-input)
    (end-of-buffer)
    (insert cmd)
    (eshell-send-input)
    (end-of-buffer)
    (yank)
    ))

The benefits of this function are that if you put it in a lambda function and bind it to a key like this:

(bind-keys*
    ("C-<backspace>" . (lambda () ; clear shell
                     (interactive)
                     (run-this-in-eshell "clear 1"))))

It will first kill the current input, run clear 1 and then yank the input back. This way you can also clear eshell from any other buffer using the keybinding.

Some other functions provided will wipe out any buffer they are ran in. So if you used the keybinding to clear eshell from some other buffer, it will instead clear THAT buffer.

0

The doc string of eshell/clear says:

(eshell/clear &optional SCROLLBACK)

Scroll contents of eshell window out of sight, leaving a blank window. If SCROLLBACK is non-nil, clear the scrollback contents.

So call clear t on the Eshell prompt to clear all Eshell buffer contents.

For binding of the command to a key you can use something like the following in eshell-mode-hook:

(local-set-key (kbd "C-<backspace>") (lambda () (interactive) (eshell/clear 1)))

This answer is similar to scribe's answer and I initially wanted just to comment that one. But, then I thought that this answer goes a bit further. It also gives you a hint on how to use Eshell commands and how to discover their comments yourself.

  • I updated my answer. :) – scribe Dec 20 '19 at 4:45

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.