How to preserve list indentation after RET in markdown-mode?

Question

When I'm editing a markdown-mode document with a list like this:

* foo
* bar
  * baz

and my cursor is at the very end of the baz line, and I press RET (which is bound to markdown-enter-key) then the baz line gets dedented so the file looks like this:

* foo
* bar
* baz

But what I would like is for the indentation to behave like most programming modes, i.e. keep baz where it was, and on the newline align my cursor with the baz bullet point so I can start typing another bullet point at that level, e.g.

* foo
* bar
  * baz
  * 

How can I configure my emacs to do this?

Answer 1

I made a new command for your request, the idea is:

• when the point is outside a list, just insert a newline as usual
• when the point is inside a list
  • if the current list is empty, delete it and insert a newline
  • otherwise, insert a new list item

(defun markdown-enter-key-dwim ()
  (interactive)
  (require 'subr-x)                     ; Needs Emacs 24.4
  (if-let ((bounds (markdown-cur-list-item-bounds))
           (beg (car bounds)) (end (cadr bounds))
           (text (buffer-substring beg end)))
      (if (and (>= (length text) 2)
               (string-blank-p
                (substring text 2)))
          (progn
            ;; Delete current blank list
            (kill-region beg end)
            ;; Insert RET
            (markdown-enter-key))
        ;; Create a new list
        (call-interactively #'markdown-insert-list-item))
    ;; Not within a list environment
    (markdown-enter-key)))

(require 'markdown-mode)
(define-key markdown-mode-map2 (kbd "RET") #'markdown-enter-key-dwim)

Notes, markdown-enter-key-dwim is not well-tested (probably too aggressive) and needs future work. The built-in M-RET (markdown-insert-list-item) is still handy enough for me, maybe you can just use it as well.