search keys and replace by values in another file?

Question

I have a dictionary key-values dict.tsv file like this:

key1 value1
key2 value2
key3 value3

And my text.txt file has this:

blah blah asdf saf key2 asd blah key1
blah key1
blah key2
blah key3

How do I get this:

blah blah asdf saf key2/value2 asd blah key1/vaue1
blah key1/value1
blah key2/value2
blah key3/value3

I imagine a function working like this:

lookup-and-replace-with-an-association-list works like this

1. M-x lookup-and-replace-with-an-association-list RET
2. Input path to dict.tsv and use the whole file content for lookup and replace. Or if no file provided, select the content from current highlighted region.
3. (internally) Parse the content to a association list dict.list
4. Input key regex pattern. If no pattern given, take all the keys in the dict.list.
5. Input replace pattern with value. In my case: keyX/valueX.
6. Optional, maybe a interactive confirmation yes, no or do-all would be nice.

Answer 1

Here's something that seems to do what you want:

(defun my/multy-key-replace (keys target)
  (interactive "fFile to read the keys from: 
fFile to replace: ")
  (let ((repbuffer (get-buffer-create "*Replacements*")))
    (with-temp-buffer
      (insert-file-contents keys)
      (let ((replacements (make-hash-table :test 'equal)))
        (while (re-search-forward "^\\([^ ]+\\) \\([^ ]+\\)$" nil t)
          (setf (gethash (match-string 1) replacements)
                (match-string 2)))
        (with-current-buffer repbuffer
          (erase-buffer)
          (insert-file-contents target)
          (maphash
           (lambda (key value)
             (goto-char (point-min))
             (replace-string key (format "%s/%s" key value)))
           replacements))))
    (pop-to-buffer repbuffer)))