Trouble understanding load/load-path relationship

Question

I'm working on a small function to recursively load my Emacs customizations. In writing it, I noticed the argument of load, MUST-SUFFIX, requires the FILE argument to not include a directory name to capitalize on the suffix "autodetection" behavior (I only want it to load based on load-suffixes).

I thought I'd try temporarily setting load-path, since the description of load also mentions:

This function searches the directories in `load-path'.

When I tried setting load-path in a let to the current directory, it wouldn't load any of the files. However, when I temporarily appended it to the beginning of load-path, it seemed to work.

I'm wondering what the difference is. Since I am making use of functions from dash.el and cl-lib, do these need to be in load-path?

Here is what I wrote (sorry it's a bit jumbled, I threw it together rather quickly, since my current solution for the same task much slower):

(defun my-load-recursive (directory)
  (let ((load-path (cons directory load-path))
        (dir-contents
         (->> (directory-files directory nil nil 'nosort)
              (-remove
               (lambda (element)
                 (or (string-equal element ".")
                     (string-equal element ".."))))
              (-separate
               (lambda (file)
                 (file-regular-p
                  (expand-file-name file directory)))))))
    (destructuring-bind (files dirs) dir-contents
      (nconc
       (delq
        nil
        (mapcar
         (lambda (file)
           (when (load file 'noerror 'nomessage nil 'mustsuffix)
             (expand-file-name file directory)))
         (delete-dups (mapcar 'file-name-base files))))
       (car
        (mapcar
        #'my-load-recursive
        (mapcar
         (lambda (dir)
           (expand-file-name dir directory))
         dirs)))))))

Answer 1

When I tried setting load-path in a let to the current directory, it wouldn't load any of the files.

Make sure that load-path is still a list, and not just a directory path string.

e.g. this:

(let ((load-path (list "/path/to/directory")))
  ...)

and never this:

(let ((load-path "/path/to/directory"))
  ...)

In addition, remember that libraries very commonly require (or otherwise load, potentially indirectly) other libraries, and as such, clobbering the load-path completely is not necessarily a good idea.

Directories in load-path are looked at in the order of the list, so consing your directory to the front of the list (exactly as you ended up doing) will give that directory priority when Emacs looks for libraries, and is therefore going to be a more robust approach in general:

(let ((load-path (cons "/path/to/directory" load-path)))
  ...)