How to merge Git conflicts in Emacs

Question

My recent Git merge has resulted in a large number of conflicts. My current approach is to search for the next occurence of '<<<' and then perform the merge by standard text editing.

Question: is there a way Emacs can support merging using the information availabe in Git about my version, their version and the base version of the file?

---

Edit: This question has a different scope than this related question, since it is not limited to invoking ediff.

Answer 1

You might want to try out smerge-mode just open the conflicted file and do M-xsmerge-modeRET. It will highlight all the conflicted regions. It also adds keybindings to easily resolve the conflicts, consult its documenation C-hfsmerge-modeRET to know them.

Default prefix

I find the default prefix for smerge-mode C-c^ cumbersome so I have changed it to C-cv

(setq smerge-command-prefix "\C-cv")

Important keybindings

For me the most important bindings are:

• smerge-next bound to smerge-command-prefixn to move to next conflict.
• smerge-previous bound to smerge-command-prefixp to move to previous conflict.
• smerge-keep-current bound to smerge-command-prefixRET to keep the version the cursor is on.
• smerge-keep-mine bound to smerge-command-prefixm to keep your changes.
• smerge-keep-other bound to smerge-command-prefixo to keep other changes.
• smerge-ediff bound to smerge-command-prefixE to start an ediff session to merge the conflicts. This is same as vc-resolve-conflicts (thanks @phils and @Malabarba for pointing this out).

Enabling smerge-mode automatically

UPDATE: The following is relevant only on Emacs versions before 25.1, the following can cause problems on later versions, see https://github.com/magit/magit/issues/3897

Additionally you might be interested in automatically enabling smerge-mode when visiting a file/buffer with conflict markers you can use something like the following to achieve this

(defun my-enable-smerge-maybe ()
  (when (and buffer-file-name (vc-backend buffer-file-name))
    (save-excursion
      (goto-char (point-min))
      (when (re-search-forward "^<<<<<<< " nil t)
        (smerge-mode +1)))))

(add-hook 'buffer-list-update-hook #'my-enable-smerge-maybe)

Note that I am using buffer-list-update-hook and not find-file-hook since most of the times I get conflicts in a buffer which is already open in emacs in which case find-file-hook is of no help.

Also check other methods mentioned in this answer.

Answer 2

Edit: since this answer got more upvotes than I expected, I expanded it a bit.

To supplement the answer by @IqbalAnsari, you could also use vc-resolve-conflicts (as mentioned by others, it is an alias to smerge-ediff). This will start the ediff interface. On the left will be the first merge parent, and the second merge parent on the right. They are labelled on the modeline with MINE and OTHER respectively (Edit: In newer Emacs, these are now labelled as UPPER=HEAD* and LOWER=<sha>*). The merged buffer is shown below (see screenshot).

Keybindings

• Navigate through the conflicts with n and p.
• Accept versions with a or b.
• Look at the ancestor with /!
• Quit the ediff session with q.

You can also navigate to the merged buffer with other-window and hand-edit in case resolving a conflict is more complicated than accepting a version. When you are done, you can save the buffer and quit Emacs as usual. For more help, just use ? during the ediff session, there are a whole bunch of very useful commands in there. I still don't know what half of them do!

Answer 3

If you happen to use Spacemacs, I'd recommend activating "smerge-transient-state", which brings up a hydra menu with all possible smerge commands.

To do that, simply call M-x spacemacs/smerge-transient-state/body, which is per default assigned to SPC-g-r.

Here's a screenshot:

Editing your file should then be intuitive:

1. Press n to go to the next hunk.
2. Choose a merge action.
3. Repeat until done.

EDIT: Solution for those without Spacemacs, adapted from John Kitchin's scimax, which I take is based off of the spacemacs solution and Iqbal's accepted answer above.

(use-package hydra)
(use-package smerge
  :config
  (defhydra scimax-smerge (:color red :hint nil)
    "
Navigate       Keep               other
----------------------------------------
_p_: previous  _c_: current       _e_: ediff
_n_: next      _m_: mine  <<      _u_: undo
_j_: up        _o_: other >>      _r_: refine
_k_: down      _a_: combine       _q_: quit
               _b_: base
"
    ("n" smerge-next)
    ("p" smerge-prev)
    ("c" smerge-keep-current)
    ("m" smerge-keep-mine)
    ("o" smerge-keep-other)
    ("b" smerge-keep-base)
    ("a" smerge-keep-all)
    ("e" smerge-ediff)
    ("j" previous-line)
    ("k" forward-line)
    ("r" smerge-refine)
    ("u" undo)
    ("q" nil :exit t))

  (defun enable-smerge-maybe ()
    (when (and buffer-file-name (vc-backend buffer-file-name))
      (save-excursion
        (goto-char (point-min))
        (when (re-search-forward "^<<<<<<< " nil t)
          (smerge-mode +1)
          (scimax-smerge/body))))))