Use-package for a mode

Question

it's not clear for me how should I set use-package to load a package when a mode is activated.

I have read different things about :mode, :init :config and I am now confused. Could someone explains it to me ?

A good exemple to me would be to start yasnipped in prog-mode.

Answer 1

The below snippet does the following:

• It calls yas-minor-mode when prog-mode-hook is called.
• The yasnippet package gets loaded/required automatically when yas-minor-mode is called. So if you do not open a buffer with a prog-mode derived major mode, then yas-minor-mode is not called, and so yasnippet is not loaded at all.
• Once yasnippet is loaded, yas-reload-all is called.

Please see the comments in below snippet for explanation.

(use-package yasnippet
  :commands (yas-minor-mode) ; autoload `yasnippet' when `yas-minor-mode' is called
                                        ; using any means: via a hook or by user
                                        ; Feel free to add more commands to this
                                        ; list to suit your needs.
  :init ; stuff to do before requiring the package
  (progn
    (add-hook 'prog-mode-hook #'yas-minor-mode))
  :config ; stuff to do after requiring the package
  (progn
    (yas-reload-all)))

For macros like use-package, the pp-macroexpand-last-sexp command is very valuable; simply put the cursor after the ending parenthesis of the macro form and call that command. For the above snippet, you will see,

(progn
  (unless
      (fboundp 'yas-minor-mode)
    (autoload #'yas-minor-mode "yasnippet" nil t))
  (condition-case-unless-debug err
      (progn
        (add-hook 'prog-mode-hook #'yas-minor-mode))
    (error
     (ignore
      (display-warning 'use-package
                       (format "%s %s: %s" "yasnippet" ":init"
                               (error-message-string err))
                       :error))))
  (eval-after-load 'yasnippet
    '(progn
       (condition-case-unless-debug err
           (progn
             (yas-reload-all))
         (error
          (ignore
           (display-warning 'use-package
                            (format "%s %s: %s" "yasnippet" ":config"
                                    (error-message-string err))
                            :error))))
       t)))

Answer 2

As the README will tell you, the :mode keyword allows you to define a deferred binding (i.e. on-demand), which will load the package when visiting a buffer which filename matches the expression you provided.

The :init and :config keywords are what you are looking for:
They allow you to respectively execute code before and after the package is loaded.

Keeping this in mind, here's what you could do to only load yasnippet in prog-mode buffers:

(use-package yasnippet
  :ensure t
  :init (add-hook 'prog-mode-hook #'yas-minor-mode)
  :config (yas-reload-all))

Using this snippet, yasnippet will actually be loaded on startup, but will only be enabled in the buffers which major mode derive from prog-mode. The appropriate snippets (if any) will then be loaded just-in-time.