Org Mode Default to Alt-Enter for Bullets

Question

I want org-mode to default to alt-enter when under bullets, so that for bullets I can just press enter to make a new bullet.

So for instance:

• Banana
• Apple
• Kiwi [MOUSE CURSOR HERE]

When I press enter, I want the following behavior (which happens when I press M-enter):

• Banana
• Apple
• Kiwi
• [MOUSE CURSOR HERE]

Instead of:

• Banana
• Apple
• Kiwi

[MOUSE CURSOR HERE]

That is the default for most other applications, but why not for org-mode?

This would greatly improve my workflow. But I don't know how! Thanks in advance.

Answer 1

The package org-autolist that does this has been available from MELPA for almost two years.

See https://github.com/calvinwyoung/org-autolist

Answer 2

You might give this version a try. It adds items and headings with regular return, and with double return on an empty entry terminates the list. It also modifies return in a table to add rows or terminate a table on an empty row. Its lightly tested ;)

(defun scimax/org-return ()
  "Add new list or headline "
  (interactive)
  (cond
   ((org-in-item-p)
    (if (org-element-property :contents-begin (org-element-context))
    (org-insert-heading)
      (beginning-of-line)
      (kill-line)
      (org-return)))
   ((org-at-heading-p)
    (if (not (string= "" (org-element-property :title (org-element-context))))
    (org-insert-heading)
      (beginning-of-line)
      (kill-line)
      (org-return)))
   ((org-at-table-p)
    (if (-any?
     (lambda (x) (not (string= "" x)))
     (nth
      (- (org-table-current-dline) 1)
      (org-table-to-lisp)))
    (org-return)
      ;; empty row
      (beginning-of-line)
      (kill-line)
      (org-return)))
   (t
    (org-return))))

(define-key org-mode-map (kbd "RET")
  'scimax/org-return)

Answer 3

You can do it like this:

 (defun my/org-list-new-item ()
   (interactive)
   (if (org-in-item-p) (org-insert-heading) (org-return)))
 (define-key org-mode-map (kbd "RET") 'my/org-list-new-item)

But I really do not recommend to use it like this.