Custom sorting for agenda

Question

I'm trying to build custom agenda block which would sort completed tasks by CLOSED property. org-agenda-sorting-strategy only supports ordering by SCHEDULED and DEADLINE properties, so I guess only way to implement this is to use custom sorting function with org-agenda-cmp-user-defined. Any help would be greatly appreciated.

  ;; custom sorting for closed items (does not work)
  (defun my/org-custom-cmp (a b)
    (org-cmp-ts a b "closed")
    )

  (setq org-agenda-cmp-user-defined 'my/org-custom-cmp)

  (setq org-agenda-custom-commands
        '(("z" "Tasks Overview"
           ((tags "+TODO=\"DONE\"+CLOSED>\"<-3d>\"" ((org-agenda-cmp-user-defined 'my/org-custom-cmp)
                                                     (org-agenda-sorting-strategy '(user-defined-up))
                                                     (org-agenda-max-entries 15)
                                                     (org-agenda-overriding-header "Recently Completed Tasks")))

            ))
;; ...

Answer 1

As @lawlist said the entry's properties are stored in text properties of the corresponding lines in the agenda. We just have to extract those using get-text-property. Not every property makes it into the agenda, but there is an org-marker property telling us were the original data is. We can use that to extract whatever we like using org-entry-get.

Here's a function that provides a comparator based on any timestamp property:

(defun cmp-date-property (prop)
  "Compare two `org-mode' agenda entries, `A' and `B', by some date property.

If a is before b, return -1. If a is after b, return 1. If they
are equal return t."
  (lexical-let ((prop prop))
  #'(lambda (a b)

    (let* ((a-pos (get-text-property 0 'org-marker a))
           (b-pos (get-text-property 0 'org-marker b))
           (a-date (or (org-entry-get a-pos prop)
                       (format "<%s>" (org-read-date t nil "now"))))
           (b-date (or (org-entry-get b-pos prop)
                       (format "<%s>" (org-read-date t nil "now"))))
           (cmp (compare-strings a-date nil nil b-date nil nil))
           )
      (if (eq cmp t) nil (signum cmp))
      ))))

Just set org-agenda-cmp-user-defined to (cmp-date-property "CLOSED") and it should work:

(add-to-list 'org-agenda-custom-commands
             '("z" "Tasks Overview"
               tags "+TODO=\"DONE\"+CLOSED>\"<-3d>\""
               ((org-agenda-cmp-user-defined (cmp-date-property
                                              "CLOSED"))
                (org-agenda-sorting-strategy '(user-defined-up)))))

Two things to note: it compares the timestamps as strings which is basically fine using the default timestamp format, less fine otherwise; if the property in question doesn't exist it's value defaults to <now>.