Center text in minibuffer/echo area?

Question

Q: is there a way to center the minibuffer/echo area horizontally?

I use Emacs in a single, very wide frame split into three windows side by side. I'm usually working in the center window, with the other windows showing notes, a REPL, etc.:

+-----------+-----------+-----------+
|           |           |           |
|   notes   | EYES HERE |   notes   |
|           |           |           |
+-----------+-----------+-----------+
| echo                              |
+-----------------------------------+

When I use the minibuffer or get a message in the echo area, the text is flush with the left side of the frame. On super wide frames like the one I'm using, this placement is really inconvenient.

Is there a way to make minibuffer/echo area text show up in the center of the frame (i.e., in the middle along the x-axis)?

+-----------+-----------+-----------+
|           |           |           |
|   notes   | EYES HERE |   notes   |
|           |           |           |
+-----------+-----------+-----------+
|            echo here?             |
+-----------------------------------+

In a perfect world, the minibuffer/echo area would start flush with the left margin of the active window, but I'd be glad if I could just get the text moved to the middle of the frame.

Answer 1

The following advice does this stuff in a hacky way. One disadvantage I am already aware of is that the spaces are also inserted into the message buffer.

(advice-add #'message :filter-args #'message-filter-center)

(defun message-filter-center (args)
  "Center message string.
This is a :filter-args advice for `message`."
  (if (car args)
      (with-current-buffer (window-buffer (minibuffer-window))
    (let ((str (apply #'format-message args)))
      (list "%s" (propertize str 'line-prefix (list 'space :align-to (max 0 (/ (- (window-width (minibuffer-window)) (string-width str)) 2)))))))
    args))

EDIT: After the comment of user:blujay I use the line-prefix text property instead of the string composed of whitespaces. That text property gets through message. Fiddling with the content of the message window directly is quite more involved.

---

I've got the impression that the above version causes some strange problems (e.g., added space at the end of completed lisp-symbols on C-h f). Therefore, I also add the original version here which did not have these problems:

(advice-add #'message :filter-args #'message-filter-center)

(defun message-filter-center (args)
  "Center message string.
This is a :filter-args advice for `message`."
  (if (car args)
      (with-current-buffer (window-buffer (minibuffer-window))
    (let* ((str (apply #'format-message args))
           (filler (make-string (max 0 (/ (- (window-width (minibuffer-window)) (string-width str)) 2)) ? )))
      (list "%s%s" filler str)))
    args))