sh-script alignment issues

Question

I'm sure emacs used to do it my way, but things appear to have changed (probably years ago, I've just been living with the pain).

I want this (to conform to corp. standards):

MULTIFORM=$(
    curl -k -A http://foo.com |
    grep -m1 multiform |
    tr '=' '\n' |
    tail -1 |
    cut -d "'" -f 2
)

But emacs-25.1 insists that this is the right way to indent:

MULTIFORM=$(
    curl -k -A http://foo.com |
        grep -m1 multiform |
        tr '=' '\n' |
        tail -1 |
        cut -d "'" -f 2
         )

... quite apart from our standards, it's ugly.

I've tried messing around with sh-learn-line-indent and it offers rules like:

close-all ")"
list-intro ";"

... but playing with them gives no joy at all.

Any ideas?

Answer 1

For the indentation after the | you should be able to get the right result by going to the incorrect line (i.e. the one that starts with grep) and then do M-x smie-config-set-indent RET before "|" RET nil RET.

But smie-config is not up to the task when it comes to tweaking the behavior of the close paren in the way you want. For that you'll need actual code. One possible approach could look like:

(defun my-sh-indent-rules ()
  (when (eq ?= (char-before))
    (skip-chars-backward "[:alnum:]_=")
    (current-column)))

(add-hook 'sh-mode-hook
          (lambda ()
            (add-hook 'smie-indent-functions
                      #'my-sh-indent-rules
                      nil 'local)))

BTW, if you want to handle the | alignment "by hand" rather than via smie-config, you could do it this way:

(defun my-sh-smie-rules (orig-fun kind token)
  (pcase (cons kind token)
   (`(:before . "|") nil)
   (_ (funcall orig-fun kind token))))
(advice-add 'sh-smie-sh-rules :around #'my-sh-smie-rules)

wef: This is the final bit of the puzzle that Stefan gave me in my muddle below - how to save the customisations for next time. As he said, I needed to teach smie about my preferences eg with M-x smie-config-set-indent then run M-x smie-config-save and look at the variable smie-config. Finally, I copied those rules (in my case, just one rule) into .emacs:

(defun my-sh-indent-rules ()
  (smie-config-local '((nil :before "|" (column . 8)))))
(add-hook 'smie-indent-functions #'my-sh-indent-rules)

There may be other ways to do this eg with the commands in sh-mode eg M-x sh-learn-line-indent - but I wasn't able to get it to work.

Answer 2

The following is a broken (or incomplete) answer ... I'm trying to fix my original problem using the sh-mode calls only instead of the lower-level smie calls that Stefan was kind enough to provide, just to see if it can be done. Reading those docs and running in a fresh emacs -Q session, I did this:

M-x sh-learn-line-indent RET before "|" RET nil

The style then worked for me and indented the lines ending in "|" - but not the final ")" - I'll still need Stefan's code for that. Then:

M-x sh-name-style RET bobs
M-x sh-save-styles-to-buffer RET *scratch*

and then used that code to create this:

(defun my-sh-indent-rules ()
  (setq sh-styles-alist
        '(("bobs"
           (sh-basic-offset . 4)
           (sh-first-lines-indent . 0)
           (sh-indent-after-case . +)
           (sh-indent-after-do . +)
           (sh-indent-after-done . 0)
           (sh-indent-after-else . +)
           (sh-indent-after-if . +)
           (sh-indent-after-loop-construct . +)
           (sh-indent-after-open . +)
           (sh-indent-comment . t)
           (sh-indent-for-case-alt . ++)
           (sh-indent-for-case-label . +)
           (sh-indent-for-continuation . +)
           (sh-indent-for-do . 0)
           (sh-indent-for-done . 0)
           (sh-indent-for-else . 0)
           (sh-indent-for-fi . 0)
           (sh-indent-for-then . 0))))
  (sh-load-style "bobs"))
(add-hook 'sh-mode-hook #'my-sh-indent-rules)

... note that it has no before "|" rule. Perhaps it doesn't know how to do that?

Anyway, running that in a fresh emacs -Q session it doesn't work even after a M-x sh-load-style RET bobs, so I'm reverting to the default behaviour.

I'm happy with Stefan's smie solution above, but I'd be interested to know how to make it work with sh-mode.