External command doesn't run in GUI mode

Question

I have the following function attached to f2 key in latex mode:

(defun latex-compile ()
      "Runs pdflatex on current file"
      (interactive)
      (let* ((file-name (shell-quote-argument (buffer-file-name)))
            (process (start-process-shell-command
                           "pdflatex"
                           "*async pdflatex*"
                           (concat "pdflatex " file-name))))
            (set-process-sentinel process 'latex-sentinel)
            (setq new-window (split-window-below 30))
            (set-window-buffer new-window "*async pdflatex*")
            (other-window 1)
            (set-process-query-on-exit-flag process nil)
            (local-set-key (kbd "z") 'latex-kill-async-pdflatex)
            ))

pdflatex program is located in /usr/local/texlive/2016/bin/i386-linux. I have the following in .bash_profile and .bashrc:

PATH=$PATH:/usr/local/texlive/2016/bin/i386-linux

When I click <f2> in GUI Emacs, it says: "/usr/bin/bash: pdflatex: command not found".

But in console Emacs it works.

I have also added

(setq exec-path (append exec-path '("/usr/local/texlive/2016/bin/i386-linux")))

to .emacs, but it didn't help.

Answer 1

exec-path is how Emacs finds executables, but you're not asking Emacs to find pdflatex, you're only asking it to find a shell, and the shell is then trying to run pdflatex.

The shell will be using the PATH in its environment. Your problem is probably that the way in which you start your GUI Emacs does not involve setting that PATH value in its environment, whereas when you start terminal Emacs you're doing so from a bash session in which your bash init files have run.

(How do you start your GUI Emacs?)

You can either ensure that when GUI Emacs is started it has the desired PATH, or else you can set the value in the process-environment variable in Emacs using setenv.

You can do this temporarily for a command if you prefer. e.g.:

(let ((process-environment (copy-sequence process-environment)))
  (setenv "PATH" (concat (getenv "PATH") ":/usr/local/texlive/2016/bin/i386-linux"))
  (start-process-shell-command "path" "*path*" "echo $PATH"))

---

A modified version of the original function might look like:

(defun latex-compile ()
  "Runs pdflatex on current file"
  (interactive)
  (let ((process-environment (copy-sequence process-environment)))
    (setenv "PATH" "$PATH:/usr/local/texlive/2016/bin/i386-linux" t)
    (let* ((file-name (shell-quote-argument (buffer-file-name)))
           (process (start-process-shell-command
                     "pdflatex"
                     "*async pdflatex*"
                     (concat "pdflatex " file-name))))
      (set-process-sentinel process 'latex-sentinel)
      (setq new-window (split-window-below 30))
      (set-window-buffer new-window "*async pdflatex*")
      (other-window 1)
      (set-process-query-on-exit-flag process nil)
      (local-set-key (kbd "z") 'latex-kill-async-pdflatex))))