How to read elisp file into s-expression?

Question

I have a file of elisp code, say foo.el. I want to turn the content into a s-expression, so that I can play with it. Right now, I use the following method:

1. Read foo.el into a string.
2. Turn the string into a s-expression using read.

The code is as followed:

(read (format "(progn %s)"
              (with-temp-buffer
                (insert-file-contents "foo.el")
                (buffer-string))))

The above code works, but is there a simpler, more direct method of reading elisp file into s-expression?

Answer 1

This is a better approach I think.

(with-current-buffer (find-file-noselect "foo.el")
  (goto-char (point-min))
  (read (current-buffer)))

If you want to wrap this as you describe below, and excecute it, try this:

(defmacro my-read (fname)
  `(progn
     ,(with-current-buffer (find-file-noselect fname)
    (goto-char (point-min))
    (read (current-buffer)))))

Both of these leave the file open.

Edit: The code above only reads one sexp, so it won't read the whole file unless it is wrapped in a single pair of parens. That is basically what your solution achieves below. This code below reads them all and closes the buffer. One issue with the code below is I had to wrap it in ignore-errors because read raises an error at the end of the file. I couldn't figure out a way to not get an error or handle that particular error.

(defmacro my-read (fname)
  (let ((sexps '())
    (sexp)
    (buf (find-file-noselect fname)))
    (with-current-buffer buf
      (goto-char (point-min))
      (ignore-errors
    (while (setq sexp (read buf))
      (message "%s" sexp)
      (push sexp sexps))))
    (kill-buffer buf)

    `(progn
       ,@(reverse sexps))))

Answer 2

Based on John Kitchin's solution, I come up with the following solution which inserts the needed text before and after the file contents:

(with-temp-buffer
  (save-excursion
    (insert "(progn\n")
    (insert-file-contents "foo.el")
    (goto-char (point-max))
    (insert "\n)\n"))
  (read (current-buffer)))