Arithmetics in a regex in a lisp function

Question

I want to replace all hard column widths in several LaTeX-documents, e.g. replace {90mm} by {0.75\textwidth}. I already found out that you can use \, and #1 to so arithmetics on captured groups, like e.g. here. But I can't get it to work in a lisp function. I tried several things to no avail, and now would like if this is possible at all, and if yes, how.

Here's something that I came up with that doesn't work:

(defun colum-width-relative ()
  ""
  (interactive)
  (beginning-of-buffer)
  (save-excursion 
    (query-replace-regexp 
     "{\\([0-9]+\\)mm}"
     (concat "{0." \,(/ (* #1 100) 120) "\\\\textwidth}"))))

Answer 1

Here's an example. See if I understood the problem correctly.

(defun colum-width-relative ()
  ""
  (interactive)
  (beginning-of-buffer)
  (save-excursion
    (while (re-search-forward "{\\([0-9]+\\)mm}" nil t)
      (replace-match
       (format "{%0.2f\\\\textwidth}"
               (/ (string-to-number (match-string 1)) 120.0))))))

---

Here's an extended version:

(defun colum-width-relative (arg)
  (interactive "P")
  (beginning-of-buffer)
  (cl-labels ((replacer
               (&rest _)
               (format "{%0.2f\\\\textwidth}"
                       (/ (string-to-number (match-string 1)) 120.0))))
    (let ((re "{\\([0-9]+\\)mm}"))
      (save-excursion
        (if arg
            (perform-replace re (list #'replacer) t t nil)
          (while (re-search-forward re nil t)
            (replace-match (replacer))))))))

If you call the extended version with prefix argument, i.e. C-u M-xcolumn-width-relative it will query you before replacing every instance matching regular expression.