Org-mode: Exclude specific headlines from TOC when exporting

Question

Q: How can I tell org-mode to exclude specific headlines from the table of contents when exporting?

For example, exporting

* Headline 1: Put me in TOC
* Headline 2: Put me in TOC
* Headline 3: DO NOT put me in TOC

to HTML produces

...
<div id="text-table-of-contents">
  <ul>
    <li><a href="#sec-1">1. Headline 1: Put me in TOC</a></li>
    <li><a href="#sec-2">2. Headline 2: Put me in TOC</a></li>
    <li><a href="#sec-3">3. Headline 3: DO NOT put me in TOC</a></li>
  </ul>
</div>
...

but I want it to produce

...
<div id="text-table-of-contents">
  <ul>
    <li><a href="#sec-1">1. Headline 1: Put me in TOC</a></li>
    <li><a href="#sec-2">2. Headline 2: Put me in TOC</a></li>
  </ul>
</div>
...

The Table of contents section of the org-mode manual doesn't have any information on this.

Also, I know that I can keep org-mode from exporting headlines by setting the COMMENT keyword via C-c ; (org-toggle-comment) or by tagging them with :noexport:. While this does keep affected headlines from showing up in the TOC, it also causes their contents to be omitted from the resulting document, which is not what I want.

Answer 1

Note that as of 2014-10-03 20:06:34 (GMT) check of UNNUMBERED is built-in already

Org uses org-export-collect-headlines to collect headlines that should be in the TOC. This function already includes two criteria for excluding headlines: the headline depth and whether it is a "footnote section" (*), so it is easy to add another one.

See the modified version of org-export-collect-headlines below. This version makes it possible to prevent a headline from showing up in the TOC by setting the NOTOC property.

* Section 1: shows up in the TOC

* Section 2: modified Org code (not in the TOC)
  :PROPERTIES:
  :NOTOC:    t
  :END:

  This is the modified =org-export-collect-headlines=:

  #+BEGIN_SRC elisp
  (defun org-export-collect-headlines (info &optional n)
    "Collect headlines in order to build a table of contents. [...]

  Return a list of all exportable headlines as parsed elements.
  Footnote sections, if any, will be ignored."
    (let ((limit (plist-get info :headline-levels)))
      (setq n (if (wholenump n) (min n limit) limit))
      (org-element-map (plist-get info :parse-tree) 'headline
        #'(lambda (headline)
            (unless (or (org-element-property :NOTOC headline)               ; new condition
                        (org-element-property :footnote-section-p headline)) ; old condition
              (let ((level (org-export-get-relative-level headline info)))
                (and (<= level n) headline))))
        info)))
  #+END_SRC

** Sub-section
   This shows up in the TOC: property inheritance is off by default.

(*) I don't know what "footnote sections" are, though.

This works for export backends that build the TOC manually. LaTeX, Beamer, and Texinfo backends don't.

By adding this advice to org-export-numbered-headline-p one can make headlines with the UNNUMBERED property export as \section*{...}, excluding them from TOC when exporting to LaTeX and Beamer:

(advice-add 'org-export-numbered-headline-p :around
            (lambda (orig headline info)
              (and (funcall orig headline info)
                   (not (org-element-property :UNNUMBERED headline)))))