Detecting variable changed outside customize

Question

I have used "Customize" to set a value for semantic-lex-c-preprocessor-symbol-file. However, after loading up .emacs, this isn't the value I see. On opening up the "Customize" menu for this variable, I see that its state is "Changed outside customize". How do I find it where this was changed? Also, what is the right way of customizing variables to avoid such issues?

Answer 1

It is not easy to find where such a change was made. The easiest way to find it is to recursively bisect your init file, to find out which part of it causes this.

To do that you can use command comment-region. With C-u it uncomments the region. Comment out 1/2, then 3/4, then 7/8, then 15/16,... of your init file.

Beyond that, code such as this will detect which variables have been changed outside Customize (but I think you already know which variables are concerned):

(let ((vars  ()))
  (mapatoms
   (lambda (symbol)
     (let ((cval  (or (get symbol 'customized-value)
                      (get symbol 'saved-value)
                      (get symbol 'standard-value))))
       (when (and cval                  ; It is declared with defcustom.
                  (default-boundp symbol) ; It has a value.
                  (not (equal (eval (car cval)) ; Value does not match customize's.
                              (default-value symbol))))
         (push symbol vars)))))
  (message "Variables changed outside: %s" vars))

If you want to let something change a value outside Customize, but you want Customize to consider that it was changed inside Customize, you can do it using library cus-edit+.el. See also Customizing and Saving on Emacs Wiki.

As for the right way to avoid such issues: use Customize to change and save the value. But you already did that. As you say, some other code seems to be changing the value after your saved value is loaded.

(Wrt where to let Customize save changes, I recommend that you use a separate custom-file, instead of letting Customize write stuff to your init file.)

Answer 2

Emacs version 26.1 and higher allows you to trigger the debugger when a variable changes. Place the following code near the beginning of your init.el:

(debug-on-variable-change 'semantic-lex-c-preprocessor-symbol-file)

Restart your emacs. Each time the variable is changed, you'll enter the debugger with the corresponding backtrace. After each occurence you can press c to continue the execution.

For more information see the elisp manual.

The second part of your question was answered accurately by Drew. Personally, I would recommend keeping the custom-set-variables block at the end of your init file.