Read-string does not always return a value

Question

I have written a small function to search MDN docs and display them on the browser.

However, sometimes the function does not work and an empty query is made.

My code is as follows:

(defun search-mdn (&optional querystring)                                       
  (interactive)                                                                 
  (if (not querystring)                                                         
      (search-mdn (read-string "What do you want to look up on MDN? "))         
      )                                                                         
  (let* ( (header "https://developer.mozilla.org/en-US/search?q=")              
         (footer "&topic=api&topic=css&topic=canvas&topic=html&topic=http&topic\
=js&topic=mobile&topic=apps&topic=svg&topic=webdev&topic=webext&topic=webgl")   
         (searchurl (concat header querystring footer)))                        
    (browse-url searchurl)                                                      
    )                                                                           
  )                     

Every time I call the function without parameters (search-mdn (read-string "What ...")) runs, however sometimes it does not call the search-mdn function with a parameter, although I enter one.

Answer 1

What @DoMiNeLa10 says is that you should have written:

(defun search-mdn (querystring)                                       
  (interactive
   (list (read-string "What do you want to look up on MDN? ")))
  (let* ((header "https://developer.mozilla.org/en-US/search?q=")
         (footer "&topic=api&topic=css&topic=canvas&topic=html&topic=http&topic\
=js&topic=mobile&topic=apps&topic=svg&topic=webdev&topic=webext&topic=webgl")
         (searchurl (concat header querystring footer)))
    (browse-url searchurl)))

Now the reason why this fixes your problem is not because using interactive magically fixes the problem: the root of your problem was simply that the (let ...) part of the code was written after the if rather than within the "else" part of the if, so when querystring is nil, your code first calls itself recursively with a valid string, and then continues execution "again" with the nil value.