Start two separate emacs daemons for console and GUI

Question

Typically I start emacs with the GUI, and start a server right away with (server-start). Now I can easily open documents into my existing emacs session from terminal via emacsclient -n <file>, or from the File Browser.

From time to time, however, I want to run emacs inside my terminal using emacsclient -t. This happens most often when writing git commit logs or performing other very small tasks. In those instances, the fact that my init file was loaded in a GUI instance of emacs means that I don't get any of my customizations that are specific to TTY emacs.

I know that I can run

emacs -nw -q -l "some-custom-init-file.el"

but that will reload all of the packages every time. Can I have the best of both worlds? Is there a way to set up a "TTY daemon" so that I can use separate customizations for running inside the terminal versus visiting the file in an existing emacs window?

Answer 1

Use emacs --daemon=your-server-name -l "custom-init-file" to start a new server and emacsclient -nw -s your-server-name to connect to it from the terminal itself. The section on Using Emacs as a server in the manual has more initialization options.

Answer 2

In addition to @Vamsi's answer, you can get many of the same benefits while running only a single server by attaching advice to make-frame-command.

For example, while running in the terminal I want the background color to be black (which maps to #202020) but I want to use #202020 in a graphical mode. I implemented this with:

(defadvice make-frame-command (after make-frame-change-background-color last activate)
  "Adjusts the background color for different frame types. 
Graphical (X) frames should have the theme color, while terminal frames should match the terminal color (which matches the theme color...but terminal frames can't directly render this color)"
    (if (display-graphic-p)
        (set-background-color "#202020")
      (set-background-color "black")))

You can get a lot of mileage out of this using make-variable-frame-local (set-background-color in the above is already frame-local).

I don't know if this is the best pattern, but if you have relatively few differences between TTY-mode and X-mode Emacs it can make configuration management easier.

The above code was pulled from my .emacs.d.

Answer 3

You don't need an advice to change settings of different frames running in the same emacs daemon. Just use the hook after-make-frame-functions like so

(defvar my/ttheme 'tango-dark)
(defvar my/gtheme 'tango)
(defun my/frame-configuration (frame)
  "configure the current frame depending on the frame type"
  (with-selected-frame frame
    (if (display-graphic-p)
        (progn
          (message "after-make-frame-functions hook: window system")
          (set-frame-size frame 115 60)
          ;; other settings for a graphical frame
          (load-theme my/gtheme t))
      (message "after-make-frame-functions hook: text console")
      (load-theme my/ttheme t)
      (set-frame-parameter frame 'menu-bar-lines 0))))

(add-hook 'after-make-frame-functions 'my/frame-configuration)

;; normal start without daemon
(if (not (daemonp))
  (my/frame-configuration (selected-frame)))

Defining it this way has the added bonus, that it set's the desired frame-configuration even if you don't start in daemon mode.

Unfortunately load-theme is not frame local and so the other frames get coloured too if you really use different themes for text and graphical frames.

Bonus information: configure your terminals with at least 256 colors to get the real feel of your selected theme. Use a setting like this in one of your shell startup files:

TERM=xterm-256color
export TERM