Determine the face(s) that would be applied to a character inserted at point, after font-lock does its thing?

Question

Suppose I am trying to write a major mode. In this mode, certain ordinary characters should have special "electric" behavior when typed, but only in some contexts (e.g. in code but not in strings or comments). The definition of "some contexts" is very complicated, but it's neatly summarized by the syntax highlighting: if the character x, inserted at point, would be given a particular face by font-lock, then the characters shouldn't have electric behavior, otherwise they should.

So I'm imagining that I could somehow write

(defun mymode-maybe-electric-squiggle ()
  (interactive)
  (if (or (not mymode-electricity)      ; user option
          (memq (faces-of-hypothetically-inserted-character ?x)
             'mymode-literal-face))
      (call-interactively 'self-insert-command)
      ;; else do the electric thing
))

But I can't figure out how to write faces-of-hypothetically-inserted-character. The x shouldn't go on the undo list, and the buffer shouldn't visibly have an x in it for a moment while I give font-lock a chance to run, and how would I give font-lock a chance to run in the middle of a command, anyway?

(For purposes of this question, please assume that there isn't any other feasible way to make the decision.)

Answer 1

I don't think "inserting x and seeing the resulting font-lock highlighting" is a good approach in general. You'll likely be better off calling asking directly the code that performs this font-lock highlighting (which should be able to make this decision directly).

But FWIW, here's how you could do it "by asking font-lock" like you suggest:

(add-hook 'post-self-insert-hook #'my-electric-squiggle nil t)

(defun my-electric-squiggle ()
  (when (and mymode-electricity
             (eq last-command-event ?~)
             (eq last-command-event (char-before))
             (not (memq (my-hypothetical-x-faces)
                        '(mymode-literal-face))))
    (do-some-thing)))

(defun my-hypothetical-x-faces ()
  (catch 'my-undo
    (atomic-change-group
      ;; Remove the squiggle that was just inserted
      (delete-region (1- (point)) (point))
      (insert "X")
      (font-lock-ensure (1- (point)) (point))
      (throw 'my-undo (get-text-property (1- (point)) 'face)))))

[ Note: 100% guaranteed untested. ]

Beware: Having to temporarily modify the buffer and then undo it is rather ugly and inefficient, and it may have undesired consequences.