Elisp expressions in projectile-replace-regexp

Question

I need to execute a regular expression with case conversion in a entire project. If I run query-replace-regexp in a single file informing '\([A-Z]+\)' and '\,(downcase \1)', it works as expected. But when I try that with projectile-replace-regexp I get the following error:

Invalid use of ‘\’ in replacement text

I investigated it a bit and it seems that the elisp expression doesn't work when query-replace-regexp is not called interactively, because if I run M-: (replace-regexp "'\\([A-Z_]+'\\)" "'\\,(downcase \\1)") I also have the error above.

Am I doing something wrong or is this some limitation? If so, is there another way to achieve this?

Answer 1

The question is related to another question about non-interactive calls of query-replace-regexp. If they cannot use query-replace-read-args in projectile-replace-regexp they should at least apply query-replace-compile-replacement to the TO argument of tags-query-replace.

The following advice of projectile-replace-regexp does that for you.

(defun my-tags-query-replace-compile-replacement (fun &rest args)
  "Apply `q-r-compile-replacement' to `tags-query-replace' in FUN with ARGS."
  (cl-letf* ((old-tags-query-replace (symbol-function 'tags-query-replace))
         ((symbol-function 'tags-query-replace)
          (lambda (from to &rest other-args)
        (apply old-tags-query-replace
               from
               (query-replace-compile-replacement to t)
               other-args))))
    (apply fun args)))

(advice-add 'projectile-replace-regexp :around #'my-tags-query-replace-compile-replacement)

DISCLAIMER: Note that I do not have projectile installed. So I cannot test the code above. Please test it and report back the test results.

NOTE: I already filed a bug-report for the problem that projectile-replace-regexp does not have the interactive features of replace-regexp.