Incremental Search after opening file

Question

Being fairly new to GNU Emacs and intend to use it as a replacement to vi/vim where possible, I came across an obstacle, I seem not be able to overcome.

In vim (similar to less) you can provide a command line argument to open the editor already highlighting the first occurrence of a search.

Searching my ways through man pages, reading help files, going through the built-in tutorial and looking on the net, all I found was specific line numbers (and columns) to jump to. However, what I am typically looking for is not at a line number I know of when opening files.

Is there an Emacs way to invoke an (incremental) search right at the start when opening a file, something along the way of emacs --search <search_term> <file>?

Answer 1

The eval solution will work, but this is a lot of stuff to type on the command-line if you use this search frequently. We can actually change the command-line parameters so that --search <string> starts up with Emacs. Just modify your initialization file with this (if you are using lexical-binding):

(add-to-list 'command-switch-alist '("--search"  . command-line-search))

(defun command-line-search (_switch)
  (let ((search-text (pop command-line-args-left)))
    (add-hook ; Use a hook that runs after files load.  Otherwise, your CLI
              ; option will have to be given AFTER any buffers that you wish to
              ; search, which is not great.
     'window-setup-hook
     #'(lambda ()
         (isearch-forward
          nil ; This should be t if you want regex searching.
          t)  ; This must be t, or the call will block, preventing the next
              ; line.
         (isearch-yank-string search-text)))))

If you have not set lexical-binding (the default), you have to live with a global variable, but this will do the trick:

(add-to-list 'command-switch-alist '("--search"  . command-line-search))

(defvar search-text nil
  "Initial text given from the CLI that will be searched.")
(defun command-line-search (_switch)
  (setq search-text (pop command-line-args-left))
  (add-hook ; Use a hook that runs after files load.  Otherwise, your CLI option
            ; will have to be given AFTER any buffers that you wish to search,
            ; which is not great.
   'window-setup-hook
   #'(lambda ()
     (isearch-forward
      nil ; This should be t if you want regex searching.
      t)  ; This must be t, or the call will block, preventing the next line.
     (isearch-yank-string search-text))))

Now all you have to do is emacs --search <search_term> <file> like you wanted.

Answer 2

According to Preset search isearch-string from command line, you can search for PATTERN with Isearch programmatically using:

(isearch-forward nil t)
(isearch-yank-string "PATTERN")

So open FILE and search for PATTERN:

$ emacs FILE --eval '(isearch-forward nil t)'  --eval '(isearch-yank-string "PATTERN")'

And if you put the following in your init file

(defun my-search-for (pattern)
  "Search for PATTERN with Isearch."
  (interactive "sSearch for: ")
  (isearch-forward nil t)
  (isearch-yank-string pattern))

you can also type less from the command line

$ emacs FILE --eval '(my-search-for "also")'