How to increase a magic number in a file buffer on each save

Question

I want to change a magic number (or a time stamp) in a file buffer on each save. The position of the magic number in the buffer can be given through a regex with a keyword or similar.

Is there any package for this? I tried auto-insert which comes with Emacs 26, but this seems to only update on file buffer creation, not on each save.

I preferably would like to enable this on a per-file basis through file local variables.

I tried a custom hack via before-save-hook, but struggled to add a function to this hook through afile variable declaration.

Answer 1

C-h f time-stamp:

time-stamp is an autoloaded interactive compiled Lisp function in
`time-stamp.el'.

(time-stamp)

  Probably introduced at or before Emacs version 19.31.

Update the time stamp string(s) in the buffer.
A template in a file can be automatically updated with a new time stamp
every time you save the file.  Add this line to your init file:
    (add-hook 'before-save-hook 'time-stamp)
or customize `before-save-hook' through Custom.

If you want to do this in the local variables section, you need to use the 'eval' functionality. e.g. assuming a .c file:

/* Local Variables: */
/* eval: (add-hook 'before-save-hook 'time-stamp 0 t) */
/* End: */

will cause the local value of before-save-hook to containg time-stamp.

Answer 2

Easily done via a file-local variable save-count. The only drawback is that you cannot define the format of the magick number freely but you are bound to the format of file-local variables.

(defvar save-count nil
  "To be used as file-local variable.
Number of times the buffer file has been saved.")

(put 'save-count 'safe-local-variable #'numberp)

(defun start-save-count (&optional remove)
  "Start counting saves for the current buffer file."
  (interactive "P")
  (if remove
      (delete-file-local-variable 'save-count)
    (add-file-local-variable 'save-count 0))
  (normal-mode))

(defun update-save-count ()
  "Increment file local variable `save-count' if its value is a number."
  (when (numberp save-count)
    (cl-incf save-count)
    (save-excursion
      (add-file-local-variable 'save-count save-count))))


(add-hook 'before-save-hook #'update-save-count)

If you do not set the value of save-count to a number you do not get the counter.

That offers you several possibilities:

• Preferred way: You can call M-x start-save-count. That command adds save-count to the list of file local variables in the current buffer. It also runs normal-mode for that variable to become effective.
• You can just add a file local variable save-count with numeric value to your file. This will automatically be incremented on saves.
• You can globally set save-count to a numeric value. In that case all buffers will get such a value on first save.
• You can set the buffer-local value of save-count with (setq-local save-count 0). Then you get the save count just for that buffer file.