How to determine which program is running inside an emacs shell buffer?

Question

I have an emacs shell buffer which may or may not be running a certain interactive program such as ftp or python. I wish to write a lisp function which will interact with this program, but I would first like to make sure that said program is indeed running. My question is therefore:

Is there a Lisp function designed to inquire which program, if any, is running inside a given shell buffer?

Such programs often set their own prompt, so I thought of using

(buffer-substring (car comint-last-prompt) (cdr comint-last-prompt)) 

to determine the current prompt, but prompts often get garbled, so I found this not to be the ideal solution. Another attempt involved using

(shell-command-to-string "pgrep -fa MYPROGRAM")

but this would risk a false positive in case MYPROGRAM is running somewhere else in the system, other than under my shell buffer.

Answer 1

Here's a simple function that gets the pid of the process running in the current buffer and then calls the pstree command to get the process tree of that process:

(defun iproc ()
  (interactive)
  (let ((pid (process-id (get-buffer-process (current-buffer)))))
    (shell-command (format "pstree -p %d" pid))))

If I have a *shell* buffer running bash, run bash again to create a subshell and then run python3 in the subshell, I do M-x iproc and get the following output:

bash(4231)---bash(12567)---python3(12603)

Of course, the pids are going to be different. Also the function needs some error checking: if the current buffer does not have a process running, the function fails. Here's a slightly better version:

(defun iproc ()
  (interactive)
  (let ((process (get-buffer-process (current-buffer))))
    (if process
        (shell-command (format "pstree -p %d" (process-id process)))
      (message "No process"))))

Answer 2

You should start with Process Information:

(process-command (get-buffer-process "*Python*"))
==> ("python3" "-i")
(process-status (get-buffer-process "*Python*"))
==> run

You should not be running ftp and python under bash under Emacs, but rather use the specific modes for them (e.g., M-x run-python &c).

If you insist on doing it your way, you should use process sentinels.

Answer 3

Updated, integrated solution from @Nickd

(defun ar-process-at-point (&optional arg)
  "Report state of current process buffer.

With optional \\[universal-argument]: keep previous reports"
  (interactive "P")
  (get-buffer-create "Report Process")
  (let ((proc (format "Process: %s\n" (process-name (get-buffer-process (current-buffer)))))
    (proc-command (format "Process: %s\n" (process-command (get-buffer-process (current-buffer)))))
        (pid (progn (shell-command (format "pstree -p %d" (process-id (get-buffer-process (current-buffer)))) "Report Process")
            (with-current-buffer "Report Process" (buffer-substring-no-properties (point-min) (point-max)))))
    (fe (format "field-end (point): %s\n" (field-end (point))))
    (fb (format "field-beginning (point): %s\n" (field-beginning (point))))
    (fap (format "(field-at-pos (point)): %s\n" (field-at-pos (point))))
    (po (format "(point): %s\n" (point)))
    (lbp (format "(line-beginning-position): %s\n" (line-beginning-position)))
    (iftm (format "inhibit-field-text-motion lbp: %s\n" (let ((inhibit-field-text-motion t)) (line-beginning-position))))
    (pf (format "process-filter: %s\n" (ignore-errors process-filter)))
    (pm (format "(process-mark process): %s\n" (ignore-errors (process-mark (get-buffer-process (current-buffer)))))))
    (save-excursion
      (delete-other-windows)
      (split-window)
      (set-buffer (get-buffer-create "Report Process"))
      (unless (eq 4 (prefix-numeric-value arg)) (erase-buffer))
      (goto-char (point-max))
      (insert proc)
      (insert proc-command)
      (insert pm)
      (insert pid)
      (insert fe)
      (insert fb)
      (insert fap)
      (insert po)
      (insert lbp)
      (insert iftm)
      (insert pf)
      (newline 1)
      (unless (eq 4 (prefix-numeric-value arg)) (goto-char (point-min)))
      (display-buffer "Report Process")
      (other-buffer))))