Punctuation abbrevs for writing prose, and automatic full stops at the end of line?

Question

I'm a beginner Emacs user, and English isn't my first language so please bear with me.

I use Emacs for writing prose, and I need help with punctuation.

To put it short, I want to turn this:
--hello strangerRET

into this:
–Hello stranger.

I want to use dashes instead of quotations to write dialogue, either an en-dash and an em-dash. With other software, I have simply made an auto correction from two short dashes -- to a longer dash. But with Emacs an abbrev needs a space in the end, which I don't want to put there, also I haven't figured out how to make abbrevs with punctuation only.

I also need this to work with some form of automatic capitalization mode so that the mode understands the dash as the beginning of a word like it does with a quotation mark.

The reason I do it like this is the keyboard I use and the fact I have this method in my muscle memory from using it elsewhere.

Also, I'd like to get a fullstop at the end of a line if no other punctuation exists there.

One more thing, I know there is some key command that you can use to delete a selected block of text where it just sends it to the bottom of the buffer rather than killing it. Can somebody point me to it?

Answer 1

One approach is to redefine the return command. Here is a command the does what you want I think. Then, I redefine in the org-mode keymap (you could do this in some other map if you use it.

(defun dash-return (&optional ignore)
  (interactive "P")
  (if ignore
      (org-return)
    (let ((p (point)))
      (goto-char (line-beginning-position))
      (cond
       ;; not on a quote so go back and return
       ((not (looking-at "--"))
    (goto-char p))
       ;; on a quote, so 
       (t
    ;; replace -- with –
    (setf (buffer-substring (point) (+ 2 (point))) "–")
    ;; Capitalize the first word
    (capitalize-word 1)
    ;; Make sure there is a period at the end, skip spaces back t0 end.
    (goto-char (line-end-position))
    (skip-chars-backward " ")
    (when (not (looking-back "[!?.]" 1))
      (insert "."))))
      (org-return))))

(define-key org-mode-map (kbd "RET") 'dash-return)

This should act like org-return when not on a line that starts with -- I think, and you can use C-u ret to avoid the reformatting.

For the other command you mentioned, I am not familiar with one, but here is a simple way to get that:

(defun send-region-to-end (r1 r2)
  (interactive "r")
  (let ((text (buffer-substring r1 r2)))
    (delete-region r1 r2)
    (save-excursion
      (goto-char (point-max))
      (insert "\n\n" text))))