org-capture: prompt for a target file

Question

Starting from the existing customization associated with key j, is there a way to view and modify the target file? In other words,

• by default, captured notes would go to */journal/inbox.org,
• optionally, input a different path, say */journal/pc.org.

Could you suggest ways to do that?

~/.emacs:

 '(org-capture-templates
   (quote
    (
     ("j" "Journal" entry
      (file+olp+datetree "~/Documents/write/notes/journal/inbox.org")
      "* %?
Entered on %U
  %i
  %a")
     )
    )
   )

Manual:

• Handling links
• Capture

Answer 1

One way is to write a custom function and use it as target: (function function-finding-location). But this would get complicated.

---

Another way is to use a variable as file and then use a wrapper around org-capture to set that variable to the desired file first:

(defvar my-org-capture-filename nil
  "File name for org capture template.")

(setq org-capture-templates
      '(("j" "journal" entry (file+olp+datetree my-org-capture-filename)
         "* %?
Entered on %U
  %i
  %a")))

(defun my-org-capture ()
  "Read file name to capture to."
  (interactive)
  (setq my-org-capture-filename
        (read-file-name "Capture to: " "~/Documents/write/notes/journal"
                        nil t "inbox.org"))
  (call-interactively #'org-capture))

Then use M-x my-org-capture

---

You could create a template for each file and use ji, jp etc. as key to capture. To make the group work add ("j" "journal") in the template:

(setq org-capture-templates
      '(("j" "journal")
        ("ji" "inbox.org" entry
         (file+olp+datetree "~/Documents/write/notes/journal/inbox.org")
         "* %?
Entered on %U
  %i
  %a")
        ("jp" "pc.org" entry
         (file+olp+datetree "~/Documents/write/notes/journal/pc.org")
         "* %?
Entered on %U
  %i
  %a")))

Answer 2

A simple trick that works for me is to use buffer-file-name as the filename target. Applied to your example that would be:

(setq org-capture-templates
      '(("j" "Journal" entry (file+olp+datetree buffer-file-name)
         "* %?
Entered on %U
  %i
  %a")))

In the case of such a template, my workflow is to switch first to the target orgfile, and then to invoke the template.