Global Unset Key: Backspace

Question

I want to unset the backspace key and I tried this:

(global-unset-key (kbd "<backspace>"))

Evaluating this in the buffer gives me nil but still the backspace key works as expected. How to unbind this?

After unbinding when I do C-h k on backspace it still shows me this:

DEL (translated from <backspace>) runs the command autopair-backspace, which is an interactive compiled Lisp function in `autopair.el'.

It is bound to DEL.

(autopair-backspace)

Possibly delete a pair of paired delimiters.

Answer 1

Finally figured this out, this will re-map Backspace key to C-h everywhere:

(define-key key-translation-map [?\C-h] [?\C-?])

Source: Magnar Sveen's Emacs configuration

Answer 2

Try this:

(define-key (cdar autopair--emulation-alist) (kbd "DEL") nil)

This looks very non-standard, by the way.

update:

Alright, here's a weird fix:

(setcdr (car autopair--emulation-alist)
        '(keymap (93 . autopair-skip-close-maybe)
          (91 . autopair-insert-opening)
          (41 . autopair-skip-close-maybe)
          (40 . autopair-insert-opening)
          (34 . autopair-insert-or-skip-quote)
          (13 . autopair-newline))) 

Answer 3

This is not exactly an answer to your question since it doesn't unset the DEL binding, but the following piece of code should shadow any existing binding (whether defined by autopair or any other minor/major mode or the global map):

(defun do-nothing ()
  "Don't do anything"
  (interactive))

(define-minor-mode no-backspace-mode
  "Disable the backspace key"
  :global t
  :lighter " noBackspace")

(defvar no-backspace--emulation-alist
  `((no-backspace-mode
     . ,(let ((map (make-sparse-keymap)))
          (define-key map (kbd "DEL") #'do-nothing)
          map)))) 

(add-to-list 'emulation-mode-map-alists 'no-backspace--emulation-alist)

When no-backspace-mode is active, the DEL key should not do anything. It should work as usual when no-backspace-mode is inactive.