"not in compilation buffer" error using compilation-next-error in elisp function

Question

I am getting an elisp error that fails at lisp/progmodes/compile.el within compilation-next-error function that reads "Not in a compilation buffer". The elisp function I am writing attempts to automatically jump to the first error within the compilation buffer, then copies the error and writes it to file. Here is the function. I've tried a few things so I've left the tried stuff commented while the function itself will produce the error. Perhaps the error is an obvious one for trained eyes.

(defun write-first-error-to-file()
  "function copies first error in compilation buffer and writes it to specified file"
  (interactive)
;;;  (select-window (previous-window))
;;;  (switch-to-buffer "*compilation*")
;;;  (goto-char (compilation-next-error))
  (let ((display-buffer-overriding-action '(display-buffer-same-window)))
   (compilation-next-error))
;;;  (set-mark-command nil)
;;;  (goto-char (compilation-next-error))
;;;  (setq deactivate-mark nil)
  (kill-ring-save (region-beginning) (region-end))
  (write-region (region-beginning) (region-end) "~/copybuffer.txt"))

The function attempts to do the following:

1. Declares the function as an interactive form
2. Display the compilation buffer and within it go to the next error within compilation buffer. Note, it should be the first error if this is the first command executed. This is where I am getting the aforementioned error.
3. Commented, set mark to select region
4. Commented, Advance cursor to next compilation-next-error
5. Commented, deactivate mark. At this point, the region should have been selected programmatically perhaps??
6. Save region to kill-ring
7. Write region to file! :D

As you can see there are quite a few issues with this function, perhaps someone can see what I am missing. Thanks for any help anyone can provide.

For reference, the above function produces the following error with strange error output. You can see the "Not in compilation buffer" within the error output.

×H^N%W\204s^A^N&\203þ^A^M×
ÌH^K>\204ô^AÈÍÎÏ#\210
ÐH8\211^U=\204s^A^N'\203^Y^BÞ
ÌH^K>\204^R^BÈÍÎÏ#\210
ÐH\233\204s^A^N(\2034^B
ÌH^K>\204,^BÈÍÎÏ#\210
ÐH^L=\204s^A^N\"T\211^V\"\202u^A)       b\210
\206J^BÈá^N$\"+\207" [buffer pt msg cl-struct-compilation--message-tags loc last local-variable-p compilation-locs error "Not in a compila\
tion buffer" ...] 7 ("/usr/share/emacs/24.5/lisp/progmodes/compile.elc" . 69981) "p"], 0

Answer 1

Try the following:

(defun write-first-error-to-file()
  "function copies first error in compilation buffer and writes it to specified file"
  (interactive)
  (let (beg)
    (set-buffer "*compilation*")
    (goto-char (point-min))
    (compilation-next-error 1)
    (setq beg (point))
    (compilation-next-error 1)

    (write-region beg (point) "~/copybuffer.txt")))

Execute it with M-x write-first-error-to-file.

In words:

• switch to the compilation buffer
• set point to the beginning of the buffer
• go to the next error
• remember the position of point in beg
• go to the next error
• write the region between beg and the current position of point to a file.

Note that you have to switch to the compilation buffer: otherwise compilation-next-error will fail with exactly the error message you got.

Note also that compilation-next-error takes a mandatory argument, a number telling it how many errors to move forwards (or backwards if negative). It also does not return anything useful: you seem to think that it returns the position of point in the buffer, but that's not true. Do C-h f compilation-next-error RET to get information about the function.

Finally, note that all you need to know to define a region are its beginning and its end. That means that you do not have to set a mark in your function, which is a Good Thing(TM): marks are generally used by users for navigation and having functions munge them can be very confusing. See the doc for the functions set-mark-command and set-mark (using C-h v <func> RET as above) for some additional guidance and warnings about setting marks.