Is there a quicker way to create links to attachments?

Question

I often want to create a link to the attachment I've just added. Especially when the attachment is an image and I want to show the image inline.
What I usually do is I open the attachment folder in dired mode, copy the filename, then create a link manually by writing [[attachment:the-file-name]].
I was just wondering if there's a quicker way to do this?

Answer 1

The variable org-attach-store-link-p is specifically designed for this purpose.
Adding the following line to your init file would make org push a [[attachment:file-name.ext]] type link to org-stored-links every time you add an attachment.
So after adding an attachment you can just use C-c C-l to insert the link.

(setq org-attach-store-link-p 'attached)

Answer 2

The function org-attach-dired-to-subtree creates attachments based on the marked files (or the file the cursor is on) in a dired buffer - see Attach from Dired for details, including how to bind it to a key sequence (C-c C-x a which happens to be unused by default in dired-mode).

The function org-attach-dired-to-subtree-store-links below is almost exactly a copy of org-attach-dired-to-subtree, except that instead of making attachments, it creates links that can be inserted into the Org mode buffer using org-insert-link (usually bound to C-C C-l if you follow the convention in the Org mode manual).

The description of the link is the filename of the attachment, but you can change that when you insert the link. The code also shows a binding for that function (C-c C-x l which also happens to be unused by default in dired-mode):

* foo                                                                                                           :ATTACH:
:PROPERTIES:
:ID:       7df0d4a8-1cd0-4f7b-84ec-e6b4dba6aa24
:END:

[[attachment:david-vogan-E8.pdf][E8]]
[[attachment:carrying.pdf][carrying]]
[[attachment:aurifeuillian.pdf][aurifeuillian]]

* Code

#+begin_src emacs-lisp
  (defun org-attach-dired-to-subtree-store-links (files)
    (interactive
     (list (dired-get-marked-files)))
    (unless (eq major-mode 'dired-mode)
      (user-error "This command must be triggered in a dired buffer"))
    (let ((start-win (selected-window))
          (other-win
           (get-window-with-predicate
            (lambda (window)
              (with-current-buffer (window-buffer window)
                (eq major-mode 'org-mode))))))
      (unless other-win
        (user-error
         "Can't attach to subtree.  No window displaying an Org buffer"))
      (select-window other-win)
      (dolist (file files)
        (let* ((fname (file-name-nondirectory file))
               (link (format "attachment:%s" fname))
               (desc fname))
          (push (list link desc) org-stored-links)))
      (select-window start-win)))
#+end_src


#+begin_src emacs-lisp
(add-hook
  'dired-mode-hook
  (lambda ()
    (define-key dired-mode-map (kbd "C-c C-x l") #'org-attach-dired-to-subtree-store-links))))
#+end_src

Assuming that you've done both keybindings as above, the workflow is:

• An Org mode buffer in one window
• A dired buffer in a second window
• Mark all the files that you want to attach
• C-c C-x a - that attaches all the marked files
• C-c C-x l - that stores attachment links to all the marked files
• Back in the Org mode buffer, do C-c C-l to insert each link.