can't get company-reftex-labels to work properly

Question

I have tried to set the company-backend as described on their github page and did not end up with the sweet resulting pop-up completion, in ref as in their image

My image:

their image:

What am I doing wrong? My relevant configs are as follows

(defun require-package (package &optional min-version no-refresh)
  "Install given PACKAGE, optionally requiring MIN-VERSION.
     If NO-REFRESH is non-nil, the available package lists will not be
     re-downloaded in order to locate PACKAGE."
  (if (package-installed-p package min-version)
      t
    (if (or (assoc package package-archive-contents) no-refresh)
    (package-install package)
      (progn
    (package-refresh-contents)
    (require-package package min-version t)))))

(require-package 'company)
(add-hook 'after-init-hook 'global-company-mode)
(eval-after-load "company"
  '(add-to-list
    'company-backends
    'company-auctex 
    'company-jedi 
    'company-math
    'company-reftex-citations
    'company-reftex-labels
    'company-shell
    )
  )
(setq company-dabbrev-downcase 0)
(setq company-idle-delay 0)

(require-package 'company-reftex)
(add-hook 'LaTeX-mode-hook 'turn-on-reftex) ; with AUCTeX LaTeX mode
(add-hook 'latex-mode-hook 'turn-on-reftex)   ; with Emacs latex mode
(setq reftex-plug-into-AUCTeX t)

Cheers!

Answer 1

The following snippet works for me. I use use-package, so it is slightly different, but I hope it is easy enough to edit. You can evaluate this with emacs -q and then calling M-x eval-buffer on the snippet.

(require 'package)
(setq package-user-dir (expand-file-name "~/.emacs.d/elpa/")
      package-enable-at-startup nil)
(add-to-list 'package-archives
             '("melpa" . "https://melpa.org/packages/") t)
(package-initialize)

(unless (package-installed-p 'use-package)
  (package-refresh-contents)
  (package-install 'use-package))
(eval-when-compile
  (require 'use-package))

(defcustom dotemacs-extras-directory (expand-file-name "extras"
                                                       user-emacs-directory)
  "Path for third-party packages and files."
  :type 'string
  :group 'dotemacs)

;; Enable Company
(use-package company
  :ensure t
  :custom
  (company-idle-delay 0.0 "Recommended by lsp")
  (company-ispell-available t)
  (company-ispell-dictionary (expand-file-name "wordlist"
                                               dotemacs-extras-directory))
  :config (global-company-mode 1))

;; Enable LaTeX
(use-package tex-site
  :ensure auctex
  :mode ("\\.tex\\'" . LaTeX-mode))

(add-hook 'LaTeX-mode-hook #'reftex-mode)
(add-hook 'latex-mode-hook #'reftex-mode)

(defun sb/company-latex-mode ()
  "Add backends for latex completion in company mode."
  (use-package math-symbol-lists ; Required by ac-math and company-math
    :ensure t)
  (use-package company-math
    :ensure t)
  (use-package company-reftex
    :ensure t)
  (use-package company-bibtex
    :ensure t)
  (make-local-variable 'company-backends)
  (setq company-backends
        '((
           company-capf
           ;; company-tabnine
           company-bibtex
           company-math-symbols-latex
           company-latex-commands
           company-math-symbols-unicode
           company-reftex-labels
           company-reftex-citations
           company-yasnippet
           company-files
           company-ispell
           company-dabbrev
           ))))
(dolist (hook '(latex-mode-hook LaTeX-mode-hook))
  (add-hook hook #'sb/company-latex-mode))

Both company-bibtex and company-reftex work. You can check the completion provider on the modeline or through M-x company-diag. The downside is that all the completions are merged, I do not know how to fix it. You can see this issue.