Regex to replace subset of repeated pattern

Question

ABC、DEF, GHI, JKL、MNO
PQR、STU, VWX、YZ

How do I replace all , s with 、 in the repeated pattern above?

The repeated pattern can be mapped with the regex below:

"^\\([A-Z]+、\\)\\(\\([A-Z]+\\), \\)+"

However, because the , is a subset of group \\2, even though it can be separated from its preceding letters in the regex,

there is no way to replace it using replace-regexp without some form of nested group code. Also, DEF, doesn't seem the match like GHI, and STU, with the regex.

(replace-regexp "^\\([A-Z]+、\\)\\(\\([A-Z]+\\), \\)+" "\\1\\2、")

What's the right way to do this, then?

---

Update:

@jue's answer below resulted in this:

Answer 1

In elisp you normally search for what you're looking for in a loop, potentially establishing sub-groups of interest, and then you act on the match data if the search succeeded. Here you can simply replace every , with 、 within the subgroup.

(save-excursion
  (while (re-search-forward "^[A-Z]+、\\(\\(?:[A-Z]+, \\)+\\)" nil t)
    (goto-char (match-beginning 1))
    (let ((bound (match-end 1)))
      (while (search-forward "," bound t)
        (replace-match "、")))))

Edit: Or more simply:

(save-excursion
  (while (re-search-forward "^[A-Z]+、" nil t)
    (while (re-search-forward "\\=\\([A-Z]+\\), " nil t)
      (replace-match "\\1、 "))))

That \= construct anchors the match to the current position of point, so that only the intended sequence of cases will be matched for that loop. Other options are supplying a BOUND argument to the search, or using narrowing to temporarily limit the searchable text.

---

Also, DEF, doesn't seem the match like GHI, and STU, with the regex.

That's because re-builder was highlighting the text which was referred to by back-reference \2 (being the ultimate match for that repeated subgroup) differently to the rest of the text. Try adding more matches for that group in a line, and it will become more obvious.