Changing background colour of the line at point

Question

I would like to change the background colour of the line at point. Would also like to be able to go back to the original colour.

Have used hl-line-mode to highlight the current line. Is it possible for the mode to highlight a line or region permanently? The possibility to loop through various colours would be of value too.

Basically I want to change the background colour of a line or region by iterating through a list of colours. Something simple rather than using quite complicated code such as highlight.el of Drew.

Perhaps make a simple package just to change background colour through a number of hex codes using highlight.el as inspiration.

Answer 1

Use hl-line-mode.............

Answer 2

Assuming you have (global-hl-line-mode 1) in your init, you should be able to see the current overlay with describe-char:

There is an overlay here:

face hl-line

Then it's just a matter of reading its background color with face-attribute. Here you can toggle between two colors a and b:

(defun toggle-hl-line ()
(interactive)
(let ((a "#d0691e") (b "black")
      (current-color (face-attribute 'hl-line :background)))
(cond ((string-equal current-color a)(set-face-background 'hl-line  b))
      ((string-equal current-color b)(set-face-background 'hl-line  a))
      (t (set-face-background 'hl-line  a)))))

You can see the available color names with list-colors-display.

Answer 3

I am using

$ emacs --version

GNU Emacs 29.0.50
Development version 53c0690fa28f on master branch; build date 2022-07-07.

1. Download https://www.emacswiki.org/emacs/download/highlight.el and put it under ~/src/elisp/highight.el.
2. Copy the below snippet in to a file ~/highlight-line.el

;; Ability to highlight lines

;; https://www.emacswiki.org/emacs/download/highlight.el

(load-file "~/src/elisp/highlight.el")

(defvar hlt-highlight-line-direction 1)

(defun hlt-highlight-line (start end face msgp)
  (interactive
   (list (save-excursion (point-at-bol))
         (save-excursion (point-at-eol))
         nil
         t))
  (hlt-highlight-region start end face msgp)
  (forward-line hlt-highlight-line-direction))

(defun hlt-unhighlight-line (start end face msgp)
  (interactive (list (save-excursion (point-at-bol))
                     (save-excursion (point-at-eol))
                     nil
                     t))
  (hlt-unhighlight-region start end face msgp)
  (forward-line (* -1 hlt-highlight-line-direction)))

(defun hlt-highlight-toggle-line-direction ()
  (interactive)
  (setq hlt-highlight-line-direction
        (* -1 hlt-highlight-line-direction)))

(define-key hlt-map (kbd "l") 'hlt-highlight-line)
(define-key hlt-map (kbd "L") 'hlt-unhighlight-line)
(define-key hlt-map (kbd "X") 'hlt-highlight-toggle-line-direction)

;; (setq repeat-keep-prefix nil)

(defun make-keymap-repeatable (sym)
  (map-keymap
   (lambda (_key cmd)
     (when (symbolp cmd)
       (message "%-20s ->  `%S'" (single-key-description _key) cmd)
       (put cmd 'repeat-map sym)))
   (symbol-value sym))
  (repeat-mode -1)
  (repeat-mode 1))

(make-keymap-repeatable 'hlt-map)

4. emacs -Q
5. C-x C-f highlight-line.el
6. M-x eval-buffer <return>
7. Do some highlights C-x C-x X l l l l l l
8. Switch face with n
9. Do some more highights with l l l l l l
10. Do some unhighights with L L L L L
11. Switch face with n
12. Do some more highlights with l l l l
13. Move down few lines <down> <down> <down> <down> <down> <down>
14. Start highlighting again with C-x X l l.

This is what you will see

15. At the end if you want to remove all the highlights do C-x X u r.

---

You can repeat the above procedure by eval-ing the below macro, and doing M-x highlight-line-demo

(defalias 'highlight-line-demo
   (kmacro "<f11>  C-x C-f  h  i  g  h  l  i  g  h  t  -  l  i  n  e  .  e  l  <return>  M-x  e  v  a  l  -  b  u  f  f  e  r  <return>  C-x X l  l  l  l  l  l  n  l  l  l  l  l  l  L  L  L  L  L  n  l  l  l  l  <down>  <down>  <down>  <down>  <down>  <down>  C-x X l  l  C-x 3  M-x  v  i  e  w  -  l  o  s  s  a  g  e  <return> "))