Debugging a hook function

Question

I have this code:

(add-hook
  'org-mode-hook
  (lambda ()
     (when (string-match "notes\\.org$" buffer-file-name)
       (face-remap-add-relative 'default :background "yellow"))))

and it should change the background color of the buffer where is notes.org file.

However, it doesn't work.

I have tried this as well:

(add-hook
  'org-mode-hook
  (lambda ()
     (when (string-match "notes\\.org$" buffer-file-name)
       (set-face-attribute 'default nil :background "yellow"))))

But it is still not working.

The echo area says if: Wrong type argument: stringp, nil

Any idea what am I doing wrong?

Answer 1

The following answer provides a working solution to the underlying issue of the O.P., and contains a couple of suggestions made by @Drew in both his alternative answer and in a comment underneath the original question. In terms of how to debug the issue posed by the O.P., please refer to the alternative answer by @Drew.

(add-hook 'org-mode-hook
          (lambda ()
            (when (and buffer-file-name
                       (string-match-p "notes\\.org$" buffer-file-name))
              (face-remap-add-relative 'default
                                       '(:foreground "black" :background "yellow")))))

Answer 2

buffer-file-name is returning nil, and string-match expects (needs) a string instead. So string-match raised an error telling you that.

buffer-file-name is returning nil because the current buffer is not visiting a file. The buffer in which you've turned on Org mode is not a file buffer. (E.g., it's a buffer such as *scratch*, which is not associated with a file.)

(Also, in general, if you're not going to use the match-data then you should use string-match-p, not string-match, as it's more efficient.)

For debugging, do this: M-x set-variable RET debug-on-error RET t RET. That shows you a backtrace, which lets you know which function raised the error and shows you the context/history of the evaluation.

Clearly you hadn't understood that the problem wasn't reported by function string-match. You thought it had something to do with your code about faces. Use non-nil debug-on-error to help with this kind of thing. You can customize it to t, so it's on by default: M-x customize-option RET debug-on-error t.