`defface` and `custom-set-faces`

Question

Noob here. In my .emacs.d/custom.el I have stuff like:

(defface delim-mismatch `((t (:foreground "red"))))

(custom-set-faces
  '(show-paren-mismatch delim-mismatch)
  ...
  )

But it throws "Wrong type argument: listp, delim-mismatch". I can't seem to find an example of using defface-defined faces in custom-set-faces by name.

Answer 1

As Drew pointed out, your defface definition is no good, but let’s ignore that for now.

One has to assign a face spec to a face, which delim-mismatch is not. There is, however, a way to construct a face spec that inherits from another face by using the :inherit face attribute. Alternatively, faces can be aliased.

This gives us three options:

;; use the `:inherit' face attribute
(defface delim-mismatch '((t :foreground "red"))
  "My custom delim mismatch face.")
(custom-set-faces
 '(show-paren-mismatch ((t :inherit delim-mismatch))))

;; define the face spec instead of the face itself
(defvar delim-mismatch-face-spec '((t :foreground "red"))
  "My custom delim mismatch face spec.")
(custom-set-faces
 `(show-paren-mismatch ,delim-mismatch-face-spec))

;; alias the faces
(defface delim-mismatch '((t :foreground "red"))
  "My custom delim mismatch face.")
(put 'show-paren-mismatch 'face-alias 'delim-mismatch)

The first option is the one that’s most commonly used as it’s the most flexible of the three.