keep org-mode comments on export

Question

I am drafting a document in org. Because I will have some coauthors, I will have to switch to LaTeX at some point. I am usually putting a very short description of the paragraph on top:

# why do we use the method
We use the method because it is great!

The org-mode comments get lost during the export. For now I am just doing the following

#+LATEX: % why do we use the method
We use the method because it is great!

which works but it is not very nice because it looks ugly and M-q doesn't work for reflowing. Is there a way to include the org-mode comments in the export? Or maybe there is even a better solution using tags and headings.

Answer 1

Try this

;; Don't skip `comment' or `comment-block' elements
(advice-add 'org-export--skip-p :around
            (defun my-org-export--skip-p (orig-fun &rest args)
              (pcase-let ((`(,datum ,options ,selected ,excluded) args))
                (cond
                 ((memq (org-element-type datum) '(comment comment-block))
                  ;; Don't skip
                  (ignore))
                 (t
                  (apply orig-fun args))))))

;; A generic transcoder for `comment' and `comment-block' elements
;; which works with `html', `odt' and `latex' backends.
(defun org-*-comment (comment contents info)
  (with-temp-buffer
    (insert (org-element-property :value comment))
    (when-let ((mode-fn (alist-get org-export-current-backend
                                   '((html . nxml-mode)
                                     (odt . nxml-mode)
                                     (latex . latex-mode)))))
      (funcall mode-fn)
      (comment-region (point-min) (point-max))
      (buffer-substring-no-properties (point-min) (point-max)))))

;; Teach the backends about the above transcoder
(cl-loop for backend in '(html latex odt)
         for transcoders = (org-export-backend-transcoders
                            (org-export-get-backend backend))
         do (cl-loop for els in '(comment comment-block)
                     do (setf (org-export-backend-transcoders
                               (org-export-get-backend backend))
                              (append
                               (list (cons 'comment 'org-*-comment)
                                     (cons 'comment-block 'org-*-comment))
                               transcoders))))

1. Create somefile.org with following content

# why do we use the method

#+begin_comment
... and this method
#+end_comment

We use the method because it is great!

2. If you do C-c C-e C-b l L, you get

% why do we use the method

% ... and this method

We use the method because it is great!

3. If you do C-c C-e C-b h H, you get

<!-- why do we use the method -->

<!-- ... and this method -->

<p>
We use the method because it is great!
</p>

Answer 2

Include the following source block in your org file:

#+begin_src emacs-lisp :exports results
  (defun transform-comments (backend)
    (while (re-search-forward "[:blank:]*# " nil t)
      (replace-match "#+LATEX: % ")))
    (add-hook 'org-export-before-parsing-hook #'transform-comments)
#+end_src

• This will probably have an issue if you have source code blocks in a language where # is used for comments.
• It will also change your global org-export-before-parsing-hook.
• It only works for exporting to LaTeX but is easily adaptable.
• The advantage is, that it is much more portable because you don't need to change your global config.