How can I change color of dollar sign different than font-latex-math-face in auctex?

Question

In AUCTex, my font-latex-math-face has green color that also colors $ $ or \( \) into green as well. Here I just want to have different color for dollar sign than font-latex-math-face's

Is it possible to change the color of dollar sign and \( \) into different color?

As example built-in math-mode at tex.stackexchange.com/ has this feature where dollar-sign shows up in different color:

Answer 1

If you want this

$ math delimiter gets its own face

instead of this

$ math delimiter has same face math text

do this

(defface font-latex-dollar-face
  '((t :foreground "lime green"))
  "Face for tikzpicture environment."
  :group 'font-latex-highlighting-faces)

(eval-after-load 'font-latex
  (advice-add
   'font-latex-match-dollar-math :around
   (defun font-latex-match-dollar-math--around
       (orig-fun &rest orig-args)
     (pcase-let*
         ((`(,limit)
           orig-args)
          (val (apply orig-fun orig-args))
          (beg (when val
                 (match-beginning 0)))
          (end (when val
                 (match-end 0))))
       (when (and beg
                  end
                  (save-excursion
                    (goto-char beg)
                    (looking-at-p (rx "$"))))
         (set-match-data
          (save-excursion
            (list
             (let* ((beg beg)
                    (end (progn (goto-char beg)
                                (skip-chars-forward (rx "$"))
                                (point))))
               (prog1 end
                 (add-text-properties beg end '(
                                                face font-latex-dollar-face
                                                fontified t))))
             (let* ((end end)
                    (beg (progn (goto-char end)
                                (skip-chars-backward (rx "$"))
                                (point))))
               (prog1 beg
                 (add-text-properties beg end '(face font-latex-dollar-face
                                                     fontified t)))))))
         val)))))

;; (advice-remove 'font-latex-match-dollar-math 'font-latex-match-dollar-math--around)