Void variable when defining macro containing defvar in progn

Question

I don't understand why I get (void-variable test-map) when trying to run:

(defun something--key-map (name)
  (make-symbol (concat (symbol-name name) "-map")))

(defmacro defsomething (name)
  `(progn
     (defvar ,(something--key-map name) (make-sparse-keymap))
     (message "key map %s" ,(something--key-map name))))

(defsomething test)

When I try to (macroexpand '(defsomething test)) I get (progn (defvar test-map (make-sparse-keymap)) (message "key map %s" test-map)), which when I paste it to scratch buffer, it is working. Do you know why it is not working directly?

Answer 1

Update (important)

To recognize uninterned symbols easily, set print-gensym:

(defmacro mac ()
  (let ((a (make-symbol "taffy"))
        (b (make-symbol "taffy")))
    `(eq ',a ',b)))

(macroexpand '(mac))
;; => (eq 'taffy 'taffy)

(let ((print-gensym t))
  (macroexpand '(mac)))
;; => (eq '#:taffy '#:taffy)

---

C-h f make-symbol:

Return a newly allocated uninterned symbol whose name is NAME.
Its value is void, and its function definition and property list are nil.

So

(let ((a (make-symbol "taffy"))
      (b (make-symbol "taffy")))
  (eq a b))
;; => nil

---

A:

Your defvared test-map is not the same symbol as the test-map you passed to message. Emacs allocates memory for them separately, thus of course not eq.

And the latter's value is void since it isn't defvared.

---

You didn't ask how to implement what you want, but I guess you want to know.

Replace make-symbol with intern. (C-h f intern for details.)