How to view only the current author in magit log? (as a toggle)

Question

I would like a way to press a key binding that limits the git log to the author of the current commit.

Pressing the same key again should clear the author field.

---

• Note that I'm aware of how to do this manually by pressing l-A then selecting the authors name. However it's not clear how this can be automated, some kind of function to limit by author, then to clear that limit.

• The question is quite spesific as I'm not sure which part of magit needs to be customized to support this, if it involves invoking transient or not. I've read over the magit-log.el sources but it's still not clear to me how this should be done.

• Note that this question relates to: How to filter by author in magit-log?

Answer 1

This is an updated version of @dalanicolai's answer, the command is my-magit-log-toggle-limit-to-author which can be bound to a key.

Changes include:

• Improved sha1-at-point check to work in the magit-log view even if the cursor isn't over the SHA1.
• Avoid a redundant call to magit-rev-format.
• Only access the author when toggling on.
• Report an error when the commit can't be detected.
• Replace string-match with string-prefix-p.
• Remove use of (magit-git-lines "shortlog" "-n" "-s" "-e" "HEAD") ... on my system it's very slow, rely on the author from the SHA1 instead.

(defun my-magit-log-toggle-limit-to-author ()
  "Toggle an isolated log of the current author."
  (interactive)
  (let* ((args (magit-log-arguments))
         (arg-prefix "--author=")
         (log-setup-buffer-args
          (list
           (magit-log-read-revs t)
           (cond
            ((seq-find (apply-partially #'string-prefix-p arg-prefix) (car args))
             (seq-remove (apply-partially #'string-prefix-p arg-prefix) (car args)))
            (t
             (let ((rev
                    (or (magit-commit-at-point)
                        (magit-section-value-if 'module-commit)
                        (thing-at-point 'git-revision t))))
               (unless rev
                 (error "Could not find rev at point"))
               (let ((author (magit-rev-format "%an <%ae>" rev)))
                 (append (car args) (list (concat arg-prefix author)))))))
           nil)))
    (apply #'magit-log-setup-buffer log-setup-buffer-args)))

Answer 2

I am not aware of magit (currently) providing such functionality, however, starting from C-h k l from the magit status buffer, and then further inspecting the code (the steps are a bit too many to write down here), we can come up with the following command:

(defun magit-log-toggle-limit-to-author ()
  (interactive)
  (let* ((args (magit-log-arguments))
         (rev (magit-thing-at-point 'git-revision t))
         (author (format "%s <%s>"
                         (magit-rev-format "%an" rev)
                         (magit-rev-format "%ae" rev))))
    (apply #'magit-log-setup-buffer
       (list (magit-log-read-revs t)
         (if (seq-find (apply-partially #'string-match "--author") (car args))
             (seq-remove (apply-partially #'string-match "--author") (car args))
           (append (car args) (list (concat "--author=" author))))
         nil))))

You can bind it to your preferred key.

Indeed would be nice to see this functionality getting added to magit directly (possibly with some easier/shorter code).