How to prompt for a virtual buffer (recently killed file buffer) using Ido completion?

Question

When ido-use-virtual-buffers is set to t, ido-switch-buffer shows, after the list of live buffers, a list of killed file buffers in chronological order, last killed first. Those are what Ido calls virtual buffers.

I'd like to have a command – I'll call it ido-find-virtual-buffer-file – that prompts for a virtual buffer, offering the virtual buffers from that list as completion candidates. In other words, ido-find-virtual-buffer-file would work just like ido-switch-buffer except that it would omit the list of live buffers.

This would make it a quick operation to reopen a recently killed file and in particular, if ido-find-virtual-buffer-file was bound to, say, C-c r, then C-c r RET would directly open the most recently killed file.

Answer 1

I've written this thing adapting my-ido-make-virtual-buffer-list from ido-add-virtual-buffers-to-list (cf.). I didn’t understand it 100% and even what I think I understood I might have gotten wrong. But it works. So far.

(defun my-ido-make-virtual-buffer-list ()
  "Return the list of virtual buffers – i.e. the history of killed file
buffers, last killed first – with the face ‘ido-virtual’ applied."
  ;; Make let-bindings of ‘ido-process-ignore-lists’ and ‘ido-ignored-list’
  ;; dynamic within this ‘defun’. They are used by ‘ido-ignore-item-p’.
  ;; See ‘(info "(elisp) Dynamic Binding")’.
  ;; They are bound dynamically only within ‘ido.el’, because they’re defined
  ;; using ‘defvar’ without a ‘value’ argument.
  ;; See ‘(info "(elisp) Defining Variables")’.
  (defvar ido-process-ignore-lists)
  (defvar ido-ignored-list)
  (setq ido-virtual-buffers nil)
  (let (name
        ido-temp-list
        (ido-process-ignore-lists t)
        (ido-ignored-list nil))
    (dolist (head recentf-list)
      (setq name (file-name-nondirectory head))
      ;; In case HEAD is a directory with trailing /.  See bug#14552.
      (when (equal name "")
    (setq name (file-name-nondirectory (directory-file-name head))))
      (when (equal name "")
    (setq name head))
      (and (not (equal name ""))
           (null (let (file-name-handler-alist) (get-file-buffer head)))
           (not (assoc name ido-virtual-buffers))
           (not (ido-ignore-item-p name ido-ignore-buffers))
           (file-exists-p head)
           (push (cons name head) ido-virtual-buffers)))
    (when ido-virtual-buffers
      (if ido-use-faces
      (dolist (comp ido-virtual-buffers)
        (put-text-property 0 (length (car comp))
                   'face 'ido-virtual
                   (car comp))))
      (setq ido-temp-list
        (nconc ido-temp-list
           (nreverse (mapcar #'car ido-virtual-buffers)))))))

(defun my-ido-find-virtual-buffer-file ()
  "Prompt for a virtual buffer (i.e. a recently killed file buffer) and
visit its file."
  (interactive)
  (let* ((virtual-buffer (ido-completing-read
                          "Virtual buffer: " (my-ido-make-virtual-buffer-list)
                          nil nil nil t))
         (filename (cdr (assoc virtual-buffer ido-virtual-buffers))))
    (find-file filename)))
(keymap-global-set "C-c r" #'ido-find-virtual-buffer-file)