org-present mode makes asterisk characters invisible

Question

My org-mode TODO list looks like this in Emacs:

*Angular
**Two way binding
***{{modelName}}
**Controller
***Do crud operations
***Different scopes across the application

I wanted to present it using org-present, which I enabled by doing M-x org-present. This removed all hierarchy-related asterisks and turned the visible text into a plain list:

Angular
Two way binding
{{modelName}}
Controller
Do crud operations
Different scopes across the application

I am interested in preserving the hierarchy levels for display. How can I do that in org-present-mode (or any other presentation mode for Emacs)?

Additionally, I noticed that org-present-mode doesn't get toggled when I do M-x org-present twice.

Answer 1

You're raising two separate issues.

Keeping asterisks visible

org-present calls org-present-add-overlays, which is responsible for making the leading asterisks invisible. Here is a modified version of org-present-add-overlays that you can add to your init-file to make sure asterisks stay visible:

(defun org-present-add-overlays ()
  "Add overlays for this mode."
  (add-to-invisibility-spec '(org-present))
  (save-excursion
    ;; hide org-mode options starting with #+
    (goto-char (point-min))
    (while (re-search-forward "^[[:space:]]*\\(#\\+\\)\\([^[:space:]]+\\).*" nil t)
      (let ((end (if (org-present-show-option (match-string 2)) 2 0)))
        (org-present-add-overlay (match-beginning 1) (match-end end))))
    ;; hide emphasis markers
    (let ((org-emph-re "\\([ \t('\"{]\\|^\\)\\(\\([/_=~+]\\)\\([^ \t\r\n,\"']\\|[^ \t\r\n,\"'].*?\\(?:\n.*?\\)\\{0,1\\}[^ \t\r\n,\"']\\)\\3\\)\\([- \t.,:!?;'\")}\\]\\|$\\)"))
      (while (re-search-forward org-emph-re nil t)
        (org-present-add-overlay (match-beginning 2) (1+ (match-beginning 2)))
        (org-present-add-overlay (1- (match-end 2)) (match-end 2))))))

org-present won't toggle org-present-mode

As described here, there is a separate command for ending a presentation and going back to "vanilla" org-mode. It is called org-present-quit; the default binding for it is C-c C-q, so just hit that if you want to get out of org-present-mode.

Alternatively, if you want to be able to use the org-present command as a toggle, you can advise it as follows:

(defun org-present-toggle (orig)
  (if (not org-present-mode)
      (funcall orig)
    (org-present-quit)))

(advice-add 'org-present :around #'org-present-toggle)