Probably influenced by Clojure, I more often use property lists as data-structures. Emacs most of the time indents them like this,
`(:token ,token
:token-quality ,quality) ,
while this is what I would prefer
`(:token ,token
:token-quality ,quality) .
So, I wonder, if someone has already tackled this ?
That can be achieved by changing the lisp-indent-function for emacs-lisp mode:
(add-hook 'emacs-lisp-mode-hook
(lambda () (setq-local lisp-indent-function #'common-lisp-indent-function)))
From lisp-mode.el in emacs source,
(defcustom lisp-indent-function 'lisp-indent-function
"A function to be called by `calculate-lisp-indent'.
It indents the arguments of a Lisp function call. This function
should accept two arguments: the indent-point, and the
`parse-partial-sexp' state at that position. One option for this
function is `common-lisp-indent-function'."
:type 'function
:group 'lisp)
As @wasamasa mentioned in a comment to the question, @Fuco1 (on github.com) has modified the default lisp-indent-function to fix the indentation of keywords (starting with :).
Emacs has provided the variable lisp-indent-function for the user to choose what function to use for indentation in lisp modes.
Instead of overriding the original function definition, we can create our own function and assign the above variable to that function name.
In this example,
Fuco1/lisp-indent-function in your emacs setupemacs-lisp-mode:(add-hook 'emacs-lisp-mode-hook
(lambda () (setq-local lisp-indent-function #'Fuco1/lisp-indent-function)))
The modded function is pasted below in the event the source referenced to github is lost.
;; https://github.com/Fuco1/.emacs.d/blob/af82072196564fa57726bdbabf97f1d35c43b7f7/site-lisp/redef.el#L20-L94
(defun Fuco1/lisp-indent-function (indent-point state)
"This function is the normal value of the variable `lisp-indent-function'.
The function `calculate-lisp-indent' calls this to determine
if the arguments of a Lisp function call should be indented specially.
INDENT-POINT is the position at which the line being indented begins.
Point is located at the point to indent under (for default indentation);
STATE is the `parse-partial-sexp' state for that position.
If the current line is in a call to a Lisp function that has a non-nil
property `lisp-indent-function' (or the deprecated `lisp-indent-hook'),
it specifies how to indent. The property value can be:
* `defun', meaning indent `defun'-style
\(this is also the case if there is no property and the function
has a name that begins with \"def\", and three or more arguments);
* an integer N, meaning indent the first N arguments specially
(like ordinary function arguments), and then indent any further
arguments like a body;
* a function to call that returns the indentation (or nil).
`lisp-indent-function' calls this function with the same two arguments
that it itself received.
This function returns either the indentation to use, or nil if the
Lisp function does not specify a special indentation."
(let ((normal-indent (current-column))
(orig-point (point)))
(goto-char (1+ (elt state 1)))
(parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
(cond
;; car of form doesn't seem to be a symbol, or is a keyword
((and (elt state 2)
(or (not (looking-at "\\sw\\|\\s_"))
(looking-at ":")))
(if (not (> (save-excursion (forward-line 1) (point))
calculate-lisp-indent-last-sexp))
(progn (goto-char calculate-lisp-indent-last-sexp)
(beginning-of-line)
(parse-partial-sexp (point)
calculate-lisp-indent-last-sexp 0 t)))
;; Indent under the list or under the first sexp on the same
;; line as calculate-lisp-indent-last-sexp. Note that first
;; thing on that line has to be complete sexp since we are
;; inside the innermost containing sexp.
(backward-prefix-chars)
(current-column))
((and (save-excursion
(goto-char indent-point)
(skip-syntax-forward " ")
(not (looking-at ":")))
(save-excursion
(goto-char orig-point)
(looking-at ":")))
(save-excursion
(goto-char (+ 2 (elt state 1)))
(current-column)))
(t
(let ((function (buffer-substring (point)
(progn (forward-sexp 1) (point))))
method)
(setq method (or (function-get (intern-soft function)
'lisp-indent-function)
(get (intern-soft function) 'lisp-indent-hook)))
(cond ((or (eq method 'defun)
(and (null method)
(> (length function) 3)
(string-match "\\`def" function)))
(lisp-indent-defform state indent-point))
((integerp method)
(lisp-indent-specform method state
indent-point normal-indent))
(method
(funcall method indent-point state))))))))
lisp-indent-function.
Commented
Mar 23, 2015 at 14:06
(setq lisp-backquote-indentation nil) for backquoted lists (as in the original question).
Intro to calculate-lisp-indent
A better solution is to override the function calculate-lisp-indent. In brief, calculate-lisp-indent is a function that returns the column to which a line at point should be indented. This function is what informs lisp-indent-function how much each line should be indented. (see also my post on reddit for more information).
Comparison to other Answers
The advantage that this answer has over using Fuco1's modified function is that (1) it fixes the root of the problem which lies in calculate-lisp-indent instead of just cleaning up after the wrong indentation returned by calculate-lisp-indent (2) it generalizes to quoted and backquoted lists (and it works whether they are quoted/backquoted explicitly or with the ' and `). It also works with arbitrarily nested quotes and backquotes.
The advantage this answer has over replacing lisp-indent-function with common-lisp-indent-function function is it doesn't have the side effect of messing up other elisp indentation. Elisp and common-lisp are indented differently.
How it works
This conditional (in calculate-lisp-indent) is what decides whether a sexp is indented like a function or not. What falls into it's else clause is indented like a function. What falls into it's if clause, is indented normally (under the current element). To make it indent quoted lists as data instead of as functions, we need to add more check for cases where the list is quoted in the conditional predicate.
(if (= (point) calculate-lisp-indent-last-sexp)
;; Containing sexp has nothing before this line
;; except the first element. Indent under that element.
nil
;; Skip the first element, find start of second (the first
;; argument of the function call) and indent under.
(progn (forward-sexp 1)
(parse-partial-sexp (point)
calculate-lisp-indent-last-sexp
0 t)))
This code checks the open parentheses of the sexp that's being indented. If it's sexp with in multiple sexp it checks them all. It returns t if it finds any quoted or backquoted sexps.
(let* ((positions (elt state 9))
(last (car (last positions)))
(rest (nreverse (butlast positions)))
(any-quoted-p nil)
(point nil))
(or
(when-let (char last)
(or (char-equal char ?')
(char-equal char ?`)))
(while (and rest (not any-quoted-p))
(setq point (pop rest))
(setq any-quoted-p
(or
(when-let (char point)
(or (char-equal char ?')
(char-equal char ?`)))
(save-excursion
(goto-char (1+ point))
(looking-at-p "\\(?:back\\)?quote[\t\n\f\s]+(")))))))
Bonus
If you want any list that starts with a keyword to be indented as data even if it's unquoted, add this as another check to the conditional predicate. This may be useful for macros in which plists are not quoted for convenience such as in defhydra.
(when-let (char-after (char-after (1+ containing-sexp)))
(char-equal char-after ?:))
Examples
The full code snippet I have posted below works with the case you've mentioned and more. Please try it out!
;; Your example
`(:token ,token
:token-quality ,quality)
;; Other cool examples
(quote (hi im gosu
the best vayne player))
'(i am the phantom of
the opera)
'((angel of music
hide no longer))
(backquote (past the point
no return
... the final chapter))
`(fee fi fo
fum)
;; should indent it like a function.
(iamafunction arg1
arg2
arg3)
For a more in-depth explanation of how this works, see my post on reddit.
Full Code Snippet
Here is the full code snippet.
(advice-add #'calculate-lisp-indent :override #'void~calculate-lisp-indent)
(defun void~calculate-lisp-indent (&optional parse-start)
"Add better indentation for quoted and backquoted lists."
;; This line because `calculate-lisp-indent-last-sexp` was defined with `defvar`
;; with it's value ommited, marking it special and only defining it locally. So
;; if you don't have this, you'll get a void variable error.
(defvar calculate-lisp-indent-last-sexp)
(save-excursion
(beginning-of-line)
(let ((indent-point (point))
state
;; setting this to a number inhibits calling hook
(desired-indent nil)
(retry t)
calculate-lisp-indent-last-sexp containing-sexp)
(cond ((or (markerp parse-start) (integerp parse-start))
(goto-char parse-start))
((null parse-start) (beginning-of-defun))
(t (setq state parse-start)))
(unless state
;; Find outermost containing sexp
(while (< (point) indent-point)
(setq state (parse-partial-sexp (point) indent-point 0))))
;; Find innermost containing sexp
(while (and retry
state
(> (elt state 0) 0))
(setq retry nil)
(setq calculate-lisp-indent-last-sexp (elt state 2))
(setq containing-sexp (elt state 1))
;; Position following last unclosed open.
(goto-char (1+ containing-sexp))
;; Is there a complete sexp since then?
(if (and calculate-lisp-indent-last-sexp
(> calculate-lisp-indent-last-sexp (point)))
;; Yes, but is there a containing sexp after that?
(let ((peek (parse-partial-sexp calculate-lisp-indent-last-sexp
indent-point 0)))
(if (setq retry (car (cdr peek))) (setq state peek)))))
(if retry
nil
;; Innermost containing sexp found
(goto-char (1+ containing-sexp))
(if (not calculate-lisp-indent-last-sexp)
;; indent-point immediately follows open paren.
;; Don't call hook.
(setq desired-indent (current-column))
;; Find the start of first element of containing sexp.
(parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
(cond ((looking-at "\\s(")
;; First element of containing sexp is a list.
;; Indent under that list.
)
((> (save-excursion (forward-line 1) (point))
calculate-lisp-indent-last-sexp)
;; This is the first line to start within the containing sexp.
;; It's almost certainly a function call.
(if (or
;; Containing sexp has nothing before this line
;; except the first element. Indent under that element.
(= (point) calculate-lisp-indent-last-sexp)
;; First sexp after `containing-sexp' is a keyword. This
;; condition is more debatable. It's so that I can have
;; unquoted plists in macros. It assumes that you won't
;; make a function whose name is a keyword.
;; (when-let (char-after (char-after (1+ containing-sexp)))
;; (char-equal char-after ?:))
;; Check for quotes or backquotes around.
(let* ((positions (elt state 9))
(last (car (last positions)))
(rest (reverse (butlast positions)))
(any-quoted-p nil)
(point nil))
(or
(when-let (char (char-before last))
(or (char-equal char ?')
(char-equal char ?`)))
(progn
(while (and rest (not any-quoted-p))
(setq point (pop rest))
(setq any-quoted-p
(or
(when-let (char (char-before point))
(or (char-equal char ?')
(char-equal char ?`)))
(save-excursion
(goto-char (1+ point))
(looking-at-p
"\\(?:back\\)?quote[\t\n\f\s]+(")))))
any-quoted-p))))
;; Containing sexp has nothing before this line
;; except the first element. Indent under that element.
nil
;; Skip the first element, find start of second (the first
;; argument of the function call) and indent under.
(progn (forward-sexp 1)
(parse-partial-sexp (point)
calculate-lisp-indent-last-sexp
0 t)))
(backward-prefix-chars))
(t
;; Indent beneath first sexp on same line as
;; `calculate-lisp-indent-last-sexp'. Again, it's
;; almost certainly a function call.
(goto-char calculate-lisp-indent-last-sexp)
(beginning-of-line)
(parse-partial-sexp (point) calculate-lisp-indent-last-sexp
0 t)
(backward-prefix-chars)))))
;; Point is at the point to indent under unless we are inside a string.
;; Call indentation hook except when overridden by lisp-indent-offset
;; or if the desired indentation has already been computed.
(let ((normal-indent (current-column)))
(cond ((elt state 3)
;; Inside a string, don't change indentation.
nil)
((and (integerp lisp-indent-offset) containing-sexp)
;; Indent by constant offset
(goto-char containing-sexp)
(+ (current-column) lisp-indent-offset))
;; in this case calculate-lisp-indent-last-sexp is not nil
(calculate-lisp-indent-last-sexp
(or
;; try to align the parameters of a known function
(and lisp-indent-function
(not retry)
(funcall lisp-indent-function indent-point state))
;; If the function has no special alignment
;; or it does not apply to this argument,
;; try to align a constant-symbol under the last
;; preceding constant symbol, if there is such one of
;; the last 2 preceding symbols, in the previous
;; uncommented line.
(and (save-excursion
(goto-char indent-point)
(skip-chars-forward " \t")
(looking-at ":"))
;; The last sexp may not be at the indentation
;; where it begins, so find that one, instead.
(save-excursion
(goto-char calculate-lisp-indent-last-sexp)
;; Handle prefix characters and whitespace
;; following an open paren. (Bug#1012)
(backward-prefix-chars)
(while (not (or (looking-back "^[ \t]*\\|([ \t]+"
(line-beginning-position))
(and containing-sexp
(>= (1+ containing-sexp) (point)))))
(forward-sexp -1)
(backward-prefix-chars))
(setq calculate-lisp-indent-last-sexp (point)))
(> calculate-lisp-indent-last-sexp
(save-excursion
(goto-char (1+ containing-sexp))
(parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
(point)))
(let ((parse-sexp-ignore-comments t)
indent)
(goto-char calculate-lisp-indent-last-sexp)
(or (and (looking-at ":")
(setq indent (current-column)))
(and (< (line-beginning-position)
(prog2 (backward-sexp) (point)))
(looking-at ":")
(setq indent (current-column))))
indent))
;; another symbols or constants not preceded by a constant
;; as defined above.
normal-indent))
;; in this case calculate-lisp-indent-last-sexp is nil
(desired-indent)
(t
normal-indent))))))
Final Notes
It is worth noting that this question would be better generalized as how to stop emacs from indenting quoted and unquoted lists as functions.
defcustom or two could potentially solve that.
Commented
Aug 24, 2020 at 17:21
You can override lisp-indent-function in a future-proof way using my package el-patch:
(el-patch-defun lisp-indent-function (indent-point state)
"This function is the normal value of the variable `lisp-indent-function'.
The function `calculate-lisp-indent' calls this to determine
if the arguments of a Lisp function call should be indented specially.
INDENT-POINT is the position at which the line being indented begins.
Point is located at the point to indent under (for default indentation);
STATE is the `parse-partial-sexp' state for that position.
If the current line is in a call to a Lisp function that has a non-nil
property `lisp-indent-function' (or the deprecated `lisp-indent-hook'),
it specifies how to indent. The property value can be:
* `defun', meaning indent `defun'-style
(this is also the case if there is no property and the function
has a name that begins with \"def\", and three or more arguments);
* an integer N, meaning indent the first N arguments specially
(like ordinary function arguments), and then indent any further
arguments like a body;
* a function to call that returns the indentation (or nil).
`lisp-indent-function' calls this function with the same two arguments
that it itself received.
This function returns either the indentation to use, or nil if the
Lisp function does not specify a special indentation."
(el-patch-let (($cond (and (elt state 2)
(el-patch-wrap 1 1
(or (not (looking-at "\\sw\\|\\s_"))
(looking-at ":")))))
($then (progn
(if (not (> (save-excursion (forward-line 1) (point))
calculate-lisp-indent-last-sexp))
(progn (goto-char calculate-lisp-indent-last-sexp)
(beginning-of-line)
(parse-partial-sexp (point)
calculate-lisp-indent-last-sexp 0 t)))
;; Indent under the list or under the first sexp on the same
;; line as calculate-lisp-indent-last-sexp. Note that first
;; thing on that line has to be complete sexp since we are
;; inside the innermost containing sexp.
(backward-prefix-chars)
(current-column)))
($else (let ((function (buffer-substring (point)
(progn (forward-sexp 1) (point))))
method)
(setq method (or (function-get (intern-soft function)
'lisp-indent-function)
(get (intern-soft function) 'lisp-indent-hook)))
(cond ((or (eq method 'defun)
(and (null method)
(> (length function) 3)
(string-match "\\`def" function)))
(lisp-indent-defform state indent-point))
((integerp method)
(lisp-indent-specform method state
indent-point normal-indent))
(method
(funcall method indent-point state))))))
(let ((normal-indent (current-column))
(el-patch-add
(orig-point (point))))
(goto-char (1+ (elt state 1)))
(parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
(el-patch-swap
(if $cond
;; car of form doesn't seem to be a symbol
$then
$else)
(cond
;; car of form doesn't seem to be a symbol, or is a keyword
($cond $then)
((and (save-excursion
(goto-char indent-point)
(skip-syntax-forward " ")
(not (looking-at ":")))
(save-excursion
(goto-char orig-point)
(looking-at ":")))
(save-excursion
(goto-char (+ 2 (elt state 1)))
(current-column)))
(t $else))))))
This fixes the problem for me; see it in context.
For a much hackier alternative to kaushalmodi's answer you could overwrite the lisp-indent-function similar to what Mark H. Weaver did for the scheme-indent-function to fix alignment of keywords in Guile Scheme.
I just copied the code from http://netris.org/~mhw/scheme-indent-function.el; the only change is to add a new cond clause. You may want to take the current code of lisp-indent-function instead of using this function as is.
(It's a pity that the indent functions don't expose more hooks to simplify minor changes like this.)
(defun scheme-indent-function (indent-point state)
"Scheme mode function for the value of the variable `lisp-indent-function'.
This behaves like the function `lisp-indent-function', except that:
i) it checks for a non-nil value of the property `scheme-indent-function'
\(or the deprecated `scheme-indent-hook'), rather than `lisp-indent-function'.
ii) if that property specifies a function, it is called with three
arguments (not two), the third argument being the default (i.e., current)
indentation."
(let ((normal-indent (current-column)))
(goto-char (1+ (elt state 1)))
(parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
(if (and (elt state 2)
(not (looking-at "\\sw\\|\\s_")))
;; car of form doesn't seem to be a symbol
(progn
(if (not (> (save-excursion (forward-line 1) (point))
calculate-lisp-indent-last-sexp))
(progn (goto-char calculate-lisp-indent-last-sexp)
(beginning-of-line)
(parse-partial-sexp (point)
calculate-lisp-indent-last-sexp 0 t)))
;; Indent under the list or under the first sexp on the same
;; line as calculate-lisp-indent-last-sexp. Note that first
;; thing on that line has to be complete sexp since we are
;; inside the innermost containing sexp.
(backward-prefix-chars)
(current-column))
(let ((function (buffer-substring (point)
(progn (forward-sexp 1) (point))))
method)
(setq method (or (get (intern-soft function) 'scheme-indent-function)
(get (intern-soft function) 'scheme-indent-hook)))
(cond ((or (eq method 'defun)
(and (null method)
(> (length function) 3)
(string-match "\\`def" function)))
(lisp-indent-defform state indent-point))
;; This next cond clause is the only change -mhw
((and (null method)
(> (length function) 1)
; The '#' in '#:' seems to get lost, not sure why
(string-match "\\`:" function))
(let ((lisp-body-indent 1))
(lisp-indent-defform state indent-point)))
((integerp method)
(lisp-indent-specform method state
indent-point normal-indent))
(method
(funcall method state indent-point normal-indent)))))))
lisp-indent-function ? Also there doesn't seem to be a function emacs-lisp-indent-function.
lisp-indent-function contains the indentation function by default. Assigning to this variable is identical to overwriting the default indentation function for emacs-lisp mode. (You are right, there is no special emacs-lisp-indent-function, it's just lisp-indent-function.)
Fuco1's modded function worked for me so I forked his config to make that functionality its own package. The result is here: https://git.sr.ht/~razzi/fuco1-redef-lisp-indent.el
You can install it using straight.el:
(use-package fuco1-redef-lisp-indent
:straight (:repo "https://git.sr.ht/~razzi/fuco1-redef-lisp-indent.el"))
Fuco1/lisp-indent-functionand do(add-hook 'emacs-lisp-mode-hook (lambda () (setq-local lisp-indent-function #'Fuco1/lisp-indent-function)))