Multiple major modes in one buffer (e.g., python-mode & LaTeX-mode)

Question

Using the LaTeX-package pythontex I one can insert python code into the latex document which is executed (and printed to your latex file if you want) if you run latex. I use auctex for editing latex files, however editing the python code inside the latex document is a bit painful since the buffer is in latex mode and not in python mode, so there is no help for proper indentation of the python code and no syntax highlighting.

So is there any reasonable way to mix the python mode with the latex mode? For example that the buffer automatically jumps to python mode if the point is inside a python code snipped? What do I have to add to my .emacs file to make it work? Any other ideas?

\documentclass[tikz]{standalone}
\usepackage{pgfplots}
\usepackage{pythontex}

\begin{document}

\begin{pycode}
print('test1')
def f( ):
    print('test2')

f()
\end{pycode}   

\pyc{f()}
\end{document}

Note that pythontex has multiple environments and commands which can contain pythoncode, for example pycode or pyverbatim as environments or \pyc or \py as commands.

Answer 1

MMM-mode (multiple major modes) seems exactly what you're looking for. It is mentionned on the emacs wiki. You need to define a submode class to mix LaTeX and python, specifying that python parts are delimited by the pycode LaTeX tags. Adding the following to your init file should do it:

(require 'mmm-auto)
(mmm-add-classes
 '((latex-python
    :submode python-mode
    :face mmm-default-submode-face
    :front "\\\\begin{pycode}\n"
    :back "\\\\end{pycode}\n")))

(setq mmm-global-mode 'maybe)
(mmm-add-mode-ext-class 'latex-mode nil 'latex-python)

The :front and :back keywords specify regular expressions for delimiters. The last two lines ask that mmm-mode with the latex-python class be activated by default in all buffers whose major mode is latex-mode.

See the documentation for other options (activating it manually, based on file name, or with file variables).

There are two ways to specify several delimiter pairs. First, several classes can be joined in a group. Below, instead of defining the latex-python class we define it as a group that contains the two classes latex-python-envs and latex-python-cmds (itself recognizing the \pyc{…} and \py{…} LaTeX commands).

Second, each class can specify several several delimiter pairs: class latex-python-envs below will recognize both pycode and pyverbatim LaTeX envs (~1 in :back refers to the value matched in the first parenthesized group in :front).

(mmm-add-group 'latex-python
 '((latex-python-envs
    :submode python-mode
    :face mmm-default-submode-face
    :front "\\\\begin{\\(pycode\\|pyverbatim\\)}\n"
    :back "\\\\end{~1}\n"
    :save-matches 1)

   (latex-python-cmds
    :submode python-mode
    :face mmm-default-submode-face
    :front "\\\\pyc?{"
    :back "}")))

For delimiters to be recognized you need to mmm-parse-buffer (C-c % C-b) (or mmm-parse-region, or mmm-parse-block ie a few lines around point). If you're used to insert LaTeX envs through LaTeX-insert-environment (C-c C-e) it could be convenient to advise it to run mmm-parse-block when it's done, so that MMM immediately recognizes the just inserted tags:

(advice-add 'LaTeX-insert-environment ':after 
    '(lambda (env) (mmm-parse-block 2)))