How do I suppress messages in the echo area (e.g. `Fill column set to 80 (was 80)`)?

Question

When I open a Python file I keep seeing Fill column set to 80 (was 80) message in the echo area. I know I have set it this limit , but I don't want to be keep reminded about it.

Is it possible to suppress this message?

my setup:

(add-hook 'python-mode-hook
  (lambda ()
    (setq indent-tabs-mode nil)
    (setq python-indent 4)
    (set-fill-column 80)
    (setq tab-width 4)))

Answer 1

@NickD answered the question well. But you can also do this, just to inhibit showing messages for set-fill-column:

(add-hook 'python-mode-hook
          (lambda ()
            (setq indent-tabs-mode  nil
                  python-indent     4
                  tab-width         4)
            (let ((inhibit-message  t))
              (set-fill-column 80))))

Or this:

(defun my-set-fill-column (arg)
  (let ((inhibit-message  t))
    (set-fill-column arg)))

(add-hook 'python-mode-hook
          (lambda ()
            (setq indent-tabs-mode  nil
                  python-indent     4
                  tab-width         4)
            (my-set-fill-column 80)))

Answer 2

Regarding the specific example case...

set-fill-column is a command which is only intended to be used interactively.

To set the fill column programmatically, just do this:

(setq fill-column 80)

Which is exactly what set-fill-column would do, after validating that 80 was a valid argument and displaying the message -- but you don't need anything to validate 80 as a fill column, and you don't want the message.