How can I get regexp-opt (or similar) not apply on the word with added underscore?

Question

See excerpt below for code used in emacs Cadence SKILL mode:

(cons (concat "\\<" (regexp-opt '("nil" "t") t)  "\\>")  'font-lock-constant-face)

it does a brilliant job at highlighting nil and t.
The issue is that if I have the string " nil_finder " anywhere within the code, it would highlight the part of the word which is "nil", and keep the _finder not highlighted. I want none of the " nil_finder " highlighted.
I have tried replacing the t with 'symbols or with 'words, and it did not work.
I can generate my own (many/ 1 huge) regular expression(s) to get the behavior that I need, but I read the regexp-opt returns a much more efficient regexp.
Thanks.

Answer 1

\< and \> match word boundaries.

Assuming _ is a symbol-constituent character in the buffer in question, you want to use \_< and \_> to match the beginning and end of the symbol.

See C-hig (elisp) Regexp Backslash

In rx syntax, these are symbol-start and symbol-end respectively.

Answer 2

(require 's)  ;; All we need is `s-matches-p'
(require 'rx)

Your example:

(s-matches-p (concat "\\<" (regexp-opt '("nil" "t") t) "\\>") "nil_finder")
;; t

(s-matches-p (concat "\\<" (regexp-opt '("nil" "t") t) "\\>") "nil")
;; t

Fixed:

(s-matches-p
 (concat
  (rx symbol-start)
  (regexp-opt '("nil" "t") t)
  (rx symbol-end))
 "nil_finder")
;; nil

(s-matches-p
 (concat
  (rx symbol-start)
  (regexp-opt '("nil" "t") t)
  (rx symbol-end))
 "nil")
;; t

Better way:

(s-matches-p (rx symbol-start (or "nil" "t") symbol-end) "nil_finder")
;; nil

(s-matches-p (rx symbol-start (or "nil" "t") symbol-end) "nil")
;; t