Read a sentence with completion for words from a collection

Question

Suppose we have a collection of descriptions like this:

("procedural" "functional" "high-level" "low-level" "statically-scoped" "dynamically-scoped")

Suppose that we have a database of programming languages and would like to enable the user to enter queries like this:

(or (and procedural high-level) dynamically-scoped)

with completion aid for the words from the collection. I have looked at (ido-)completing-read, but it seems to match the whole input string instead of individual words. With what tool can I achieve the desired behavior?

Answer 1

Here is a complete solution based on this discussion:

(require 'company)
(require 'cl-lib)

(defconst sample-completions
  '("procedural" "functional" "high-level" "low-level" "statically-scoped" "dynamically-scoped"))

;; This function is based on http://sixty-north.com/blog/writing-the-simplest-emacs-company-mode-backend
(defun company-sample-backend (command &optional arg &rest ignored)
  (interactive (list 'interactive))
  (let ((my-completions (copy-sequence sample-completions)))
    (cl-case command
      (interactive (company-begin-backend 'company-sample-backend))
      (prefix (and t ;(eq major-mode 'fundamental-mode)
           (company-grab-symbol)))
      (candidates
       (cl-remove-if-not
    (lambda (c) (string-prefix-p arg c))
    my-completions)))))

(define-key company-mode-map (kbd "TAB") 'company-sample-backend)

(setq resize-mini-windows t)

(defun my-minibuffer-mode ()
  (company-mode 1))

We can now perform the input without altering the normal function of the mini-buffer as follows:

(let ((company-backends (copy-sequence company-backends))
      (minibuffer-setup-hook (copy-sequence minibuffer-setup-hook)))
  (add-to-list 'company-backends 'company-sample-backend)
  (add-hook 'minibuffer-setup-hook 'my-minibuffer-mode)
  (read-from-minibuffer "Prompt: "))

Acknowledgement: thank you very much to everyone for their comments.